reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th18:
  for p1,p2,p3,p4 being Point of TOP-REAL 2,
  P being compact non empty Subset of TOP-REAL 2,
  C0 being Subset of TOP-REAL 2 st
  P={p where p is Point of TOP-REAL 2: |.p.|=1} &
  p1,p2,p3,p4 are_in_this_order_on P holds
  for f,g being Function of I[01],TOP-REAL 2 st
  f is continuous one-to-one & g is continuous one-to-one &
  C0={p8 where p8 is Point of TOP-REAL 2: |.p8.|<=1}&
  f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 &
  rng f c= C0 & rng g c= C0 holds rng f meets rng g
proof
  let p1,p2,p3,p4 be Point of TOP-REAL 2,
  P be compact non empty Subset of TOP-REAL 2,C0 be Subset of TOP-REAL 2;
  assume that
A1: P={p where p is Point of TOP-REAL 2: |.p.|=1} and
A2: p1,p2,p3,p4 are_in_this_order_on P;
  per cases by A2,JORDAN17:def 1;
  suppose LE p1,p2,P & LE p2,p3,P & LE p3,p4,P;
    hence thesis by A1,JGRAPH_5:68;
  end;
  suppose LE p2,p3,P & LE p3,p4,P & LE p4,p1,P;
    hence thesis by A1,JGRAPH_5:69;
  end;
  suppose LE p3,p4,P & LE p4,p1,P & LE p1,p2,P;
    hence thesis by A1,Th17;
  end;
  suppose LE p4,p1,P & LE p1,p2,P & LE p2,p3,P;
    hence thesis by A1,Th16;
  end;
end;
