reserve n for Nat;

theorem Th18:
  for C be compact connected non vertical non horizontal Subset of
TOP-REAL 2 holds Lower_Seq(C,n) = Rotate(Cage(C,n),E-max L~Cage(C,n))-:W-min L~
  Cage(C,n)
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  set Nmi = N-min L~Cage(C,n);
  set Nma = N-max L~Cage(C,n);
  set Wmi = W-min L~Cage(C,n);
  set Wma = W-max L~Cage(C,n);
  set Ema = E-max L~Cage(C,n);
  set Emi = E-min L~Cage(C,n);
  set Sma = S-max L~Cage(C,n);
  set Smi = S-min L~Cage(C,n);
  set RotWmi = Rotate(Cage(C,n),Wmi);
  set RotEma = Rotate(Cage(C,n),Ema);
A1: Ema in rng Cage(C,n) by SPRECT_2:46;
  Wma in L~Cage(C,n) & Nmi`2 = N-bound L~Cage(C,n) by EUCLID:52,SPRECT_1:13;
  then Wma`2 <= Nmi`2 by PSCOMP_1:24;
  then Nmi <> Wmi by SPRECT_2:57;
  then
A2: card {Nmi,Wmi} = 2 by CARD_2:57;
A3: Wmi in rng Cage(C,n) by SPRECT_2:43;
  then
A4: Cage(C,n)-:Wmi <> {} by FINSEQ_5:47;
  len(Cage(C,n)-:Wmi) = Wmi..Cage(C,n) by A3,FINSEQ_5:42;
  then (Cage(C,n)-:Wmi)/.len (Cage(C,n)-:Wmi) = Wmi by A3,FINSEQ_5:45;
  then
A5: Wmi in rng (Cage(C,n)-:Wmi) by A4,FINSEQ_6:168;
  (Cage(C,n)-:Wmi)/.1 = Cage(C,n)/.1 by A3,FINSEQ_5:44
    .= Nmi by JORDAN9:32;
  then
A6: Nmi in rng (Cage(C,n)-:Wmi) by A4,FINSEQ_6:42;
  {Nmi,Wmi} c= rng (Cage(C,n)-:Wmi)
  by A6,A5,TARSKI:def 2;
  then
A7: card {Nmi,Wmi} c= card rng (Cage(C,n)-:Wmi) by CARD_1:11;
  card rng (Cage(C,n)-:Wmi) c= card dom (Cage(C,n)-:Wmi) by CARD_2:61;
  then card rng (Cage(C,n)-:Wmi) c= len (Cage(C,n)-:Wmi) by CARD_1:62;
  then Segm 2 c= Segm len (Cage(C,n)-:Wmi) by A2,A7;
  then len (Cage(C,n)-:Wmi) >= 2 by NAT_1:39;
  then
A8: rng (Cage(C,n)-:Wmi) c= L~(Cage(C,n)-:Wmi) by SPPOL_2:18;
A9: Cage(C,n)/.1 = Nmi by JORDAN9:32;
  then Emi..Cage(C,n) <= Sma..Cage(C,n) by SPRECT_2:72;
  then Ema..Cage(C,n) < Sma..Cage(C,n) by A9,SPRECT_2:71,XXREAL_0:2;
  then
A10: Ema..Cage(C,n) < Smi..Cage(C,n) by A9,SPRECT_2:73,XXREAL_0:2;
  then
A11: Ema..Cage(C,n) < Wmi..Cage(C,n) by A9,SPRECT_2:74,XXREAL_0:2;
A12: Smi..Cage(C,n) <= Wmi..Cage(C,n) by A9,SPRECT_2:74;
  then
A13: Ema in rng (Cage(C,n)-:Wmi) by A3,A1,A10,FINSEQ_5:46,XXREAL_0:2;
  Nma`1 <= (NE-corner L~Cage(C,n))`1 by PSCOMP_1:38;
  then Nmi`1 < Nma`1 & Nma`1 <= E-bound L~Cage(C,n) by EUCLID:52,SPRECT_2:51;
  then
A14: Nmi <> Ema by EUCLID:52;
A15: not Ema in rng (Cage(C,n):-Wmi)
  proof
    (Cage(C,n):-Wmi)/.1 = Wmi by FINSEQ_5:53;
    then
A16: Wmi in rng (Cage(C,n):-Wmi) by FINSEQ_6:42;
    (Cage(C,n):-Wmi)/.len(Cage(C,n):-Wmi) = Cage(C,n)/.len Cage(C,n) by A3,
FINSEQ_5:54
      .= Cage(C,n)/.1 by FINSEQ_6:def 1
      .= Nmi by JORDAN9:32;
    then
A17: Nmi in rng (Cage(C,n):-Wmi) by FINSEQ_6:168;
    {Nmi,Wmi} c= rng (Cage(C,n):-Wmi)
    by A17,A16,TARSKI:def 2;
    then
A18: card {Nmi,Wmi} c= card rng (Cage(C,n):-Wmi) by CARD_1:11;
    Wma in L~Cage(C,n) & Nmi`2 = N-bound L~Cage(C,n) by EUCLID:52,SPRECT_1:13;
    then Wma`2 <= Nmi`2 by PSCOMP_1:24;
    then Nmi <> Wmi by SPRECT_2:57;
    then
A19: card {Nmi,Wmi} = 2 by CARD_2:57;
    card rng (Cage(C,n):-Wmi) c= card dom (Cage(C,n):-Wmi) by CARD_2:61;
    then card rng (Cage(C,n):-Wmi) c= len (Cage(C,n):-Wmi) by CARD_1:62;
    then Segm 2 c= Segm len (Cage(C,n):-Wmi) by A19,A18;
    then len (Cage(C,n):-Wmi) >= 2 by NAT_1:39;
    then
A20: rng (Cage(C,n):-Wmi) c= L~(Cage(C,n):-Wmi) by SPPOL_2:18;
    assume Ema in rng (Cage(C,n):-Wmi);
    then Ema in L~(Cage(C,n)-:Wmi) /\ L~(Cage(C,n):-Wmi) by A13,A8,A20,
XBOOLE_0:def 4;
    then Ema in {Nmi,Wmi} by Th17;
    then Ema = Wmi by A14,TARSKI:def 2;
    hence contradiction by TOPREAL5:19;
  end;
A21: Nma..Cage(C,n) <= Ema..Cage(C,n) by A9,SPRECT_2:70;
A22: Nmi..Cage(C,n) < Nma..Cage(C,n) by A9,SPRECT_2:68;
  then
A23: Nmi in rng Cage(C,n) & Nmi..Cage(C,n) < Ema..Cage(C,n) by A9,SPRECT_2:39
,70,XXREAL_0:2;
  then
A24: Nmi in rng (Cage(C,n)-:Wmi) by A3,A11,FINSEQ_5:46,XXREAL_0:2;
A25: Ema..(Cage(C,n)-:Wmi) <> 1
  proof
    assume
A26: Ema..(Cage(C,n)-:Wmi) = 1;
    Nmi..(Cage(C,n)-:Wmi) = Nmi..Cage(C,n) by A3,A23,A11,SPRECT_5:3,XXREAL_0:2
      .= 1 by A9,FINSEQ_6:43;
    hence contradiction by A22,A21,A13,A24,A26,FINSEQ_5:9;
  end;
  then Ema in rng (Cage(C,n)-:Wmi/^1) by A13,FINSEQ_6:78;
  then
A27: Ema in rng (Cage(C,n)-:Wmi/^1) \ rng (Cage(C,n):-Wmi) by A15,
XBOOLE_0:def 5;
A28: Wmi in rng (Cage(C,n):-Ema) by A3,A1,A12,A10,FINSEQ_6:62,XXREAL_0:2;
  RotWmi:-Ema = ((Cage(C,n):-Wmi)^((Cage(C,n)-:Wmi)/^1)):-Ema by A3,
FINSEQ_6:def 2
    .= ((Cage(C,n)-:Wmi)/^1):-Ema by A27,FINSEQ_6:65
    .= (Cage(C,n)-:Wmi):-Ema by A13,A25,FINSEQ_6:83
    .= (Cage(C,n):-Ema)-:Wmi by A3,A1,A12,A10,Th16,XXREAL_0:2
    .= ((Cage(C,n):-Ema)^((Cage(C,n)-:Ema)/^1))-:Wmi by A28,FINSEQ_6:66
    .= RotEma-:Wmi by A1,FINSEQ_6:def 2;
  hence thesis by JORDAN1E:def 2;
end;
