reserve m,k,j,j1,i,i1,i2,n for Nat,
  r,s for Real,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p for Point of TOP-REAL 2;

theorem Th18:
  for G being Y_equal-in-column non empty-yielding Matrix of
  TOP-REAL 2 holds card(proj2.:Values G) <= width G
proof
  let G be Y_equal-in-column non empty-yielding Matrix of TOP-REAL 2;
  deffunc F(Nat)=proj2.(G*(1,$1));
  consider f being FinSequence such that
A1: len f = width G and
A2: for k be Nat st k in dom f holds f.k = F(k) from FINSEQ_1:sch 2;
A3: dom f = Seg width G by A1,FINSEQ_1:def 3;
  proj2.:Values G c= rng f
  proof
    let y be object;
A4: Values G = { G*(i,j) where i,j is Nat: [i,j] in Indices G }
    by MATRIX_0:39;
    assume y in proj2.:Values G;
    then consider x being object such that
A5: x in the carrier of TOP-REAL 2 and
A6: x in Values G and
A7: y = proj2.x by FUNCT_2:64;
    consider i,j such that
A8: x = G*(i,j) and
A9: [i,j] in Indices G by A6,A4;
    reconsider x as Point of TOP-REAL 2 by A5;
A10: 1 <= i & i <= len G by A9,MATRIX_0:32;
A11: 1 <= j & j <= width G by A9,MATRIX_0:32;
    then
A12: j in Seg width G by FINSEQ_1:1;
    y = x`2 by A7,PSCOMP_1:def 6
      .= G*(1,j)`2 by A8,A11,A10,GOBOARD5:1
      .= proj2.(G*(1,j)) by PSCOMP_1:def 6
      .= f.j by A2,A3,A12;
    hence thesis by A3,A12,FUNCT_1:3;
  end;
  then Segm card(proj2.:Values G) c= Segm card Seg width G by A3,CARD_1:12;
  then card(proj2.:Values G) <= card Seg width G by NAT_1:39;
  hence thesis by FINSEQ_1:57;
end;
