reserve C for Simple_closed_curve,
  P for Subset of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  n for Element of NAT;
reserve D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th18:
  E-bound C = E-bound Upper_Arc C
proof
A1: E-bound Upper_Arc C >= E-bound C
  proof
A2: (E-max C)`1 = E-bound C by EUCLID:52;
    assume
A3: E-bound Upper_Arc C < E-bound C;
A4: east_halfline E-max C misses Upper_Arc C
    proof
      assume east_halfline E-max C meets Upper_Arc C;
      then consider p being object such that
A5:   p in east_halfline E-max C and
A6:   p in Upper_Arc C by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A5;
      p`1 <= E-bound Upper_Arc C by A6,PSCOMP_1:24;
      then E-bound C > p`1 by A3,XXREAL_0:2;
      hence contradiction by A2,A5,TOPREAL1:def 11;
    end;
    E-max C in east_halfline E-max C & E-max C in Upper_Arc C by JORDAN7:1
,TOPREAL1:38;
    hence contradiction by A4,XBOOLE_0:3;
  end;
  E-bound C >= E-bound Upper_Arc C by JORDAN6:61,PSCOMP_1:67;
  hence thesis by A1,XXREAL_0:1;
end;
