reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th18:
  for f being Function of TOP-REAL n,R^1,i st i in Seg n & (for p
  being Element of TOP-REAL n holds f.p=p/.i) holds f is continuous
proof
  let f be Function of TOP-REAL n,R^1,i;
  assume that
A1: i in Seg n and
A2: for p being Element of TOP-REAL n holds f.p=p/.i;
  reconsider f1=f as Function of TOP-REAL n,TopSpaceMetr(RealSpace) by
TOPMETR:def 6;
  for r being Real,u being Element of RealSpace,P
being Subset of TopSpaceMetr(RealSpace) st r>0 & P=Ball(u,r) holds f1"P is open
  proof
    let r be Real, u be Element of RealSpace, P be
    Subset of TopSpaceMetr RealSpace;
    assume that
    r>0 and
A3: P=Ball(u,r);
    reconsider u1=u as Real;
    Ball(u,r)={s:u1-r<s & s<u1+r} by Th17;
    then f"(Ball(u,r))={p where p is Element of TOP-REAL n: u1-r<p/.i &
    p/.i<u1+r} by A2,Th15;
    hence thesis by A1,A3,Th14;
  end;
  hence thesis by Th16,TOPMETR:def 6;
end;
