reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem
  1 <= i & i+1 <= len G & 1 <= j & j+1 <= width G implies cell(G,i,j) =
{ |[r,s]| : G*(i,j)`1 <= r & r <= G*(i+1,j)`1 & G*(i,j)`2 <= s & s <= G*(i,j+1)
  `2 }
proof
  set A = { |[r,s]| : G*(i,j)`1 <= r & r <= G*(i+1,j)`1 & G*(i,j)`2 <= s & s
  <= G*(i,j+1)`2 };
  assume
A1: 1 <= i & i+1 <= len G & 1 <= j & j+1 <= width G;
  now
    let p be object;
    assume
A2: p in cell(G,i,j);
    then reconsider q=p as Point of TOP-REAL 2;
A3: G*(i,j)`2 <= q`2 & q`2 <= G*(i,j+1)`2 by A1,A2,Th17;
A4: p = |[q`1,q`2]| by EUCLID:53;
    G*(i,j)`1 <= q`1 & q`1 <= G*(i+1,j)`1 by A1,A2,Th17;
    hence p in A by A4,A3;
  end;
  hence cell(G,i,j) c= A;
  now
    let p be object;
    assume p in A;
    then consider r,s such that
A5: |[r,s]| = p and
A6: G*(i,j)`1 <= r & r <= G*(i+1,j)`1 & G*(i,j)`2 <= s & s <= G*(i,j+ 1)`2;
    reconsider q=p as Point of TOP-REAL 2 by A5;
    r = q`1 & s = q`2 by A5,EUCLID:52;
    hence p in cell(G,i,j) by A1,A6,Th17;
  end;
  hence thesis;
end;
