reserve i,j,m,n,k for Nat,
  x,y for set,
  K for Field,
  a,L for Element of K;

theorem Th18:
  for K be Field, V be VectSp of K, W be Subspace of V for f be
nilpotent linear-transformation of V,V, fI be nilpotent Function of im (f|^n),
  im (f|^n) st fI = f|im (f|^n) & n <= deg f holds deg fI + n = deg f
proof
  let K be Field,V be VectSp of K,W be Subspace of V;
  let f be nilpotent linear-transformation of V,V;
  set IM=im (f|^n);
  let fI be nilpotent Function of IM,IM;
  assume
A1: fI=f|IM;
  set D=deg f;
  assume n<=D;
  then reconsider Dn=D-n as Element of NAT by NAT_1:21;
A2: now
    let x be object;
    assume x in dom (fI|^Dn);
    then reconsider X=x as Vector of IM by FUNCT_2:def 1;
    reconsider v=X as Vector of V by VECTSP_4:10;
A3: dom (f|^n) = the carrier of V by FUNCT_2:def 1;
    X in IM;
    then consider w be Element of V such that
A4: v = (f|^n).w by RANKNULL:13;
    (f|^D).w = ZeroMap(V,V).w by Def5
      .= ((the carrier of V)-->0.V).w by GRCAT_1:def 7
      .= 0.V;
    hence 0.IM = (f|^(Dn+n)).w by VECTSP_4:11
      .= ((f|^Dn)*(f|^n)).w by VECTSP11:20
      .= (f|^Dn).v by A4,A3,FUNCT_1:13
      .= ((f|^Dn) |IM).X by FUNCT_1:49
      .= (fI|^Dn).x by A1,VECTSP11:22;
  end;
  dom (fI|^Dn)=[#]IM by FUNCT_2:def 1;
  then fI|^Dn = (the carrier of IM)-->0.IM by A2,FUNCOP_1:11
    .= ZeroMap(IM,IM) by GRCAT_1:def 7;
  then
A5: deg fI<=Dn by Def5;
  deg fI = Dn
  proof
    set DI=deg fI;
A6: dom (f|^n)=the carrier of V by FUNCT_2:def 1;
    assume DI<>Dn;
    then DI<Dn by A5,XXREAL_0:1;
    then
A7: DI+n<Dn+n by XREAL_1:6;
    consider v be Vector of V such that
A8: for i st i < D holds (f|^i).v<>0.V by Th16;
    (f|^n).v in IM by RANKNULL:13;
    then
A9: (f|^n).v in the carrier of IM;
    fI|^DI = ZeroMap(IM,IM) by Def5
      .= (the carrier of IM)-->0.IM by GRCAT_1:def 7;
    then 0.IM = (fI|^DI).((f|^n).v) by A9,FUNCOP_1:7
      .= ((f|^DI) |IM).((f|^n).v) by A1,VECTSP11:22
      .= (f|^DI).((f|^n).v) by A9,FUNCT_1:49
      .= ((f|^DI)*(f|^n)).v by A6,FUNCT_1:13
      .= (f|^(DI+n)).v by VECTSP11:20;
    hence thesis by A7,A8,VECTSP_4:11;
  end;
  hence thesis;
end;
