reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th18:
  a * v1 |-- b1 = a * (v1 |-- b1)
proof
  set vb=v1 |-- b1;
  set avb=(a*v1) |-- b1;
  consider L1 be Linear_Combination of V1 such that
A1: v1 = Sum(L1) & Carrier L1 c= rng b1 and
A2: for k st 1<=k & k<=len vb holds vb/.k = L1.(b1/.k) by MATRLIN:def 7;
A3: len vb=len b1 by MATRLIN:def 7;
  reconsider rb1=rng b1 as Basis of V1 by MATRLIN:def 2;
  consider L2 be Linear_Combination of V1 such that
A4: a*v1 = Sum(L2) and
A5: Carrier L2 c= rng b1 and
A6: for k st 1<=k & k<=len avb holds avb/.k = L2.(b1/.k) by MATRLIN:def 7;
A7: len avb=len b1 by MATRLIN:def 7;
  len (a*vb)=len vb by MATRIXR1:16;
  then reconsider
  vb9=vb,avb,Avb=a*vb as Element of (len b1)-tuples_on the carrier
  of K by A3,A7,FINSEQ_2:92;
A8: rb1 is linearly-independent by VECTSP_7:def 3;
  now
    let i such that
A9: i in Seg len b1;
A10: 1<=i & i<=len b1 by A9,FINSEQ_1:1;
A11: now
      per cases;
      suppose
        a<>0.K;
        then a*L1=L2 by A1,A4,A5,A8,MATRLIN:7;
        hence L2.(b1/.i) = a*L1.(b1/.i) by VECTSP_6:def 9
          .= a*(vb9/.i) by A2,A3,A10;
      end;
      suppose
A12:    a=0.K;
        then
A13:    a*v1=0.V1 by VECTSP_1:14;
        L2 is Linear_Combination of Carrier L2 & Carrier L2 is
        linearly-independent by A5,A8,VECTSP_6:7,VECTSP_7:1;
        then not b1/.i in Carrier L2 by A4,A13;
        hence L2.(b1/.i) = 0.K .= a*(vb9/.i) by A12;
      end;
    end;
A14: dom b1=Seg len b1 by FINSEQ_1:def 3;
    dom vb=dom b1 by A3,FINSEQ_3:29;
    then
A15: vb.i=vb/.i by A9,A14,PARTFUN1:def 6;
    dom avb=dom b1 by A7,FINSEQ_3:29;
    then avb.i=avb/.i by A9,A14,PARTFUN1:def 6;
    hence avb.i = L2.(b1/.i) by A6,A7,A10
      .= Avb.i by A9,A15,A11,FVSUM_1:51;
  end;
  hence thesis by FINSEQ_2:119;
end;
