reserve X for non empty set,
  F for with_the_same_dom Functional_Sequence of X, ExtREAL,
  seq,seq1,seq2 for ExtREAL_sequence,
  x for Element of X,
  a,r for R_eal,
  n,m,k for Nat;
reserve S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S;
reserve F1,F2 for Functional_Sequence of X,ExtREAL,
  f,g,P for PartFunc of X, ExtREAL;

theorem
  E = dom(F.0) & (for n holds F.n is nonnegative & F.n is E-measurable
) & (for x,n,m st x in E & n <= m holds (F.n).x >= (F.m).x) & Integral(M,(F.0)
  |E) < +infty implies ex I be ExtREAL_sequence st (for n be Nat holds I.n =
  Integral(M,F.n)) & I is convergent & lim I = Integral(M,lim F)
proof
  assume that
A1: E = dom(F.0) and
A2: for n holds F.n is nonnegative & F.n is E-measurable and
A3: for x,n,m st x in E & n <= m holds (F.n).x >= (F.m).x and
A4: Integral(M,(F.0)|E) < +infty;
A5: F.0 is nonnegative by A2;
A6: dom(F.0) = dom(|. F.0 .|) by MESFUNC1:def 10;
A7: for x be Element of X st x in dom(F.0) holds (F.0).x = |. F.0 .|.x
  proof
    let x be Element of X;
    0 <= (F.0).x by A5,SUPINF_2:51;
    then
A8: |.(F.0).x.| = (F.0).x by EXTREAL1:def 1;
    assume x in dom(F.0);
    hence thesis by A6,A8,MESFUNC1:def 10;
  end;
A9: F.0 is E-measurable by A2;
  then Integral(M,F.0) = integral+(M,F.0) by A1,A5,MESFUNC5:88;
  then integral+(M,F.0) < +infty by A1,A4,RELAT_1:68;
  then
A10: integral+(M,|. F.0 .|) < +infty by A6,A7,PARTFUN1:5;
A11: max+(F.0) is E-measurable by A2,MESFUNC2:25;
  for x be object st x in dom max-(F.0) holds 0. <= (max-(F.0)).x
   by MESFUNC2:13;
  then
A12: max-(F.0) is nonnegative by SUPINF_2:52;
A13: for x be Element of X, n be Nat st x in E holds (|. F.n .|).x <= (F.0). x
  proof
    let x be Element of X, n be Nat;
    assume
A14: x in E;
    F.n is nonnegative by A2;
    then 0 <= (F.n).x by SUPINF_2:51;
    then |.(F.n).x.| = (F.n).x by EXTREAL1:def 1;
    then
A15: |.(F.n).x.| <= (F.0).x by A3,A14;
    dom(F.n) = dom(|. F.n .|) by MESFUNC1:def 10;
    then x in dom(|. F.n .|) by A1,A14,MESFUNC8:def 2;
    hence thesis by A15,MESFUNC1:def 10;
  end;
A16: for x be Element of X st x in E holds F#x is convergent
  proof
    let x be Element of X;
    assume
A17: x in E;
    now
      let n,m be Nat;
      assume m <= n;
      then (F.n).x <= (F.m).x by A3,A17;
      then (F#x).n <= (F.m).x by MESFUNC5:def 13;
      hence (F#x).n <= (F#x).m by MESFUNC5:def 13;
    end;
    then F#x is non-increasing by RINFSUP2:7;
    hence thesis by RINFSUP2:36;
  end;
A18: dom max+(F.0) = dom(F.0) by MESFUNC2:def 2;
  then
A19: max+(F.0)|E = max+(F.0) by A1,RELAT_1:68;
  for x be object st x in dom max+(F.0) holds 0. <= (max+(F.0)).x
   by MESFUNC2:12;
  then
A20: max+(F.0) is nonnegative by SUPINF_2:52;
  then
A21: dom(max+(F.0) + max-(F.0)) = dom max+(F.0) /\ dom max-(F.0) by A12,
MESFUNC5:22;
A22: dom max-(F.0) = dom(F.0) by MESFUNC2:def 3;
  then
A23: max-(F.0)|E = max-(F.0) by A1,RELAT_1:68;
  max-(F.0) is E-measurable by A1,A2,MESFUNC2:26;
  then ex C be Element of S st C = dom(max+(F.0) + max-(F.0)) & integral+(M,
max+(F.0) + max-(F.0)) = integral+(M,max+(F.0)|C) + integral+(M,max-(F.0)|C)
by A1,A18,A22,A20,A12,A11,MESFUNC5:78;
  then
A24: integral+(M,max+(F.0)) + integral+(M,max-(F.0)) < +infty by A1,A18,A22,A21
,A19,A23,A10,MESFUNC2:24;
  0 <= integral+(M,max-(F.0)) by A1,A9,A22,A12,MESFUNC2:26,MESFUNC5:79;
  then integral+(M,max+(F.0)) <> +infty by A24,XXREAL_3:def 2;
  then
A25: integral+(M,max+(F.0)) < +infty by XXREAL_0:4;
  0 <= integral+(M,max+(F.0)) by A1,A9,A18,A20,MESFUNC2:25,MESFUNC5:79;
  then integral+(M,max-(F.0)) <> +infty by A24,XXREAL_3:def 2;
  then integral+(M,max-(F.0)) < +infty by XXREAL_0:4;
  then F.0 is_integrable_on M by A1,A9,A25;
  then
  ex I be ExtREAL_sequence st ( for n be Nat holds I.n = Integral(M,F.n))&
  lim_inf I >= Integral(M,lim_inf F) & lim_sup I <= Integral( M,lim_sup F) &( (
  for x be Element of X st x in E holds F#x is convergent) implies I is
  convergent & lim I = Integral(M,lim F)) by A1,A2,A13,Th17;
  hence thesis by A16;
end;
