reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;

theorem Th18:
  for f be PartFunc of CNS,RNS, x0 be Point of CNS holds f
is_continuous_in x0 iff x0 in dom f & for N1 being Neighbourhood of f/.x0 ex N
  being Neighbourhood of x0 st f.:N c= N1
proof
  let f be PartFunc of CNS,RNS;
  let x0 be Point of CNS;
  thus f is_continuous_in x0 implies x0 in dom f & for N1 being Neighbourhood
  of f/.x0 ex N being Neighbourhood of x0 st f.:N c= N1
  proof
    assume
A1: f is_continuous_in x0;
    hence x0 in dom f;
    let N1 be Neighbourhood of f/.x0;
    consider N being Neighbourhood of x0 such that
A2: for x1 be Point of CNS st x1 in dom f & x1 in N holds f/.x1 in N1
    by A1,Th15;
    take N;
    now
      let r be object;
      assume r in f.:N;
      then consider x be Point of CNS such that
A3:   x in dom f and
A4:   x in N and
A5:   r=f.x by PARTFUN2:59;
      r=f/.x by A3,A5,PARTFUN1:def 6;
      hence r in N1 by A2,A3,A4;
    end;
    hence thesis;
  end;
  assume that
A6: x0 in dom f and
A7: for N1 being Neighbourhood of f/.x0 ex N being Neighbourhood of x0
  st f.:N c= N1;
  now
    let N1 be Neighbourhood of f/.x0;
    consider N being Neighbourhood of x0 such that
A8: f.:N c= N1 by A7;
    take N;
    let x1 be Point of CNS;
    assume that
A9: x1 in dom f and
A10: x1 in N;
    f.x1 in f.:N by A9,A10,FUNCT_1:def 6;
    then f.x1 in N1 by A8;
    hence f/.x1 in N1 by A9,PARTFUN1:def 6;
  end;
  hence thesis by A6,Th15;
end;
