
theorem Th18:
  for I being non empty set for A being PLS-yielding ManySortedSet
of I for b being Segre-like non trivial-yielding ManySortedSubset of Carrier A
for x being Point of A.indx(b) ex p being ManySortedSet of I st p in product b
  & {p+*(indx(b),x) qua set} = product(b+*(indx(b),{x}))
proof
  let I be non empty set;
  let A be PLS-yielding ManySortedSet of I;
  let b1 be Segre-like non trivial-yielding ManySortedSubset of Carrier A;
  set i=indx(b1);
  let x be Point of A.i;
  consider bb being object such that
A1: bb in product b1 by XBOOLE_0:def 1;
A2: ex bf being Function st bf=bb & dom bf=dom b1 &
for o being object st o in
  dom b1 holds bf.o in b1.o by A1,CARD_3:def 5;
A3: dom b1=I by PARTFUN1:def 2;
  then reconsider bb as ManySortedSet of I by A2,PARTFUN1:def 2,RELAT_1:def 18;
  take p=bb;
  thus p in product b1 by A1;
  set bbx=bb+*(i,x);
  thus {p+*(i,x) qua set}=product(b1+*(i,{x}))
  proof
    thus {p+*(i,x) qua set} c= product(b1+*(i,{x}))
    proof
A4:   now
        let z be object;
        assume z in dom (b1+*(i,{x}));
        then
A5:     z in I;
        then
A6:     z in dom bb by PARTFUN1:def 2;
        per cases;
        suppose
A7:       z=i;
          then bbx.z = x by A6,FUNCT_7:31;
          then bbx.z in {x} by TARSKI:def 1;
          hence bbx.z in (b1+*(i,{x})).z by A3,A7,FUNCT_7:31;
        end;
        suppose
A8:       z<>i;
          then bbx.z = bb.z by FUNCT_7:32;
          then bbx.z in b1.z by A1,A3,A5,CARD_3:9;
          hence bbx.z in (b1+*(i,{x})).z by A8,FUNCT_7:32;
        end;
      end;
      let o be object;
      assume o in {p+*(i,x) qua set};
      then
A9:   o = bbx by TARSKI:def 1;
      dom bbx = I by PARTFUN1:def 2
        .= dom (b1+*(i,{x})) by PARTFUN1:def 2;
      hence thesis by A9,A4,CARD_3:9;
    end;
    let o be object;
    assume o in product(b1+*(i,{x}));
    then consider u being Function such that
A10: u=o and
A11: dom u=dom (b1+*(i,{x})) and
A12: for z being object st z in dom (b1+*(i,{x})) holds u.z in (b1+*(i,{x
    }) ).z by CARD_3:def 5;
A13: now
      let z be object;
      assume
A14:  z in dom u;
      then
A15:  z in I by A11;
      reconsider zz=z as Element of I by A11,A14;
A16:  u.z in (b1+*(i,{x})).z by A11,A12,A14;
      per cases;
      suppose
A17:    zz=i;
        then u.z in {x} by A3,A16,FUNCT_7:31;
        then u.z = x by TARSKI:def 1;
        hence u.z = bbx.z by A2,A3,A17,FUNCT_7:31;
      end;
      suppose
A18:    zz<>i;
        then b1.zz is non empty trivial by PENCIL_1:def 21;
        then b1.zz is 1-element;
        then consider o being object such that
A19:    b1.z = {o} by ZFMISC_1:131;
        u.z in b1.z by A16,A18,FUNCT_7:32;
        then
A20:    u.z = o by A19,TARSKI:def 1;
        bbx.z = bb.z by A18,FUNCT_7:32;
        then bbx.z in {o} by A2,A3,A15,A19;
        hence u.z = bbx.z by A20,TARSKI:def 1;
      end;
    end;
    dom u = I by A11,PARTFUN1:def 2
      .= dom bbx by PARTFUN1:def 2;
    then u=bbx by A13;
    hence thesis by A10,TARSKI:def 1;
  end;
end;
