reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;
reserve F for random_variable of S1,S2;

theorem
  for S be finite non empty set,
  s be non empty FinSequence of S
  holds
  ex G be random_variable of
  Trivial-SigmaField (Seg len s),Trivial-SigmaField (S)
  st G = s &
 for  x be set st x in S
  holds
  (probability(G,Trivial-Probability (Seg len s))).{x}
  = FDprobability (x,s)
  proof
    let S be finite non empty set,
    s be non empty FinSequence of S;
    reconsider n = len s as non empty Element of NAT;
    reconsider G = s as random_variable of
    Trivial-SigmaField (Seg len s),Trivial-SigmaField (S) by Th16;
    take G;
    thus G = s;
    let x be set;
    assume A1: x in S;
    set y = {x};
    {x} c= S by A1, ZFMISC_1:31; then
    (probability(G,Trivial-Probability (Seg len s))).y
     = card(G"y)/card(Seg len s) by Th17
    .= card(G"y)/n by FINSEQ_1:57;
    hence thesis;
  end;
