reserve n for Nat,
  a,b for Real,
  s for Real_Sequence;

theorem
  (for n holds s.n = (-1)|^(n+1)*n|^4) implies for n holds Partial_Sums(
  s).n = (-1)|^(n+1)*n*(n+1)*(n|^2+n-1)/2
proof
  defpred X[Nat] means Partial_Sums(s).$1=(-1)|^($1+1)*$1*($1+1)*(
  $1|^2+$1-1)/2;
  assume
A1: for n holds s.n = (-1)|^(n+1)*n|^4;
A2: for n st X[n] holds X[n+1]
  proof
    let n;
    assume Partial_Sums(s).n = (-1)|^(n+1)*n*(n+1)*(n|^2+n-1)/2;
    then Partial_Sums(s).(n+1) =(-1)|^(n+1)*n*(n+1)*(n|^2+n-1)/2 + s.(n+1) by
SERIES_1:def 1
      .=(-1)|^(n+1)*n*(n+1)*(n|^2+n-1)/2 + (-1)|^(n+1+1)*(n+1)|^4 by A1
      .=((-1)|^(n+1)*(-1)*(-1)*n*(n+1)*(n|^2+n-1) + (-1)|^(n+2)*(n+1)|^4*2)/
    2
      .=((-1)|^(n+1+1)*(-1)*n*(n+1)*(n|^2+n-1)+(-1)|^(n+2)*(n+1)|^4*2)/2 by
NEWTON:6
      .=(-1)|^(n+2)*((-1)*n*(n+1)*(n|^2+n-1)+(n+1)|^(3+1)*2)/2
      .=(-1)|^(n+2)*((-1)*n*(n+1)*(n|^2+n-1)+(n+1)|^3*(n+1)*2)/2 by NEWTON:6
      .=(-1)|^(n+2)*(n+1)*((-1)*(n*n|^2+n*n-n*1)+(n+1)|^3*2)/2
      .=(-1)|^(n+2)*(n+1)*((-1)*(n|^(2+1)+n*n-n*1)+(n+1)|^3*2)/2 by NEWTON:6
      .=(-1)|^(n+2)*(n+1)*((-1)*(n|^3+n|^2-n)+(n+1)|^3*2)/2 by WSIERP_1:1
      .=(-1)|^(n+2)*(n+1)*((-1)*(n|^3+n|^2-n)+(n|^3+3*n|^2+3*n+1)*2)/2 by Lm4
      .=(-1)|^(n+2)*(n+1)*(n|^3+5*n|^2+7*n+2)/2
      .=(-1)|^(n+2)*(n+1)*((n+2)*((n+1)|^2+(n+1)-1))/2 by Lm13
      .=(-1)|^(n+2)*(n+1)*(n+2)*((n+1)|^2+(n+1)-1)/2;
    hence thesis;
  end;
  Partial_Sums(s).0 = s.0 by SERIES_1:def 1
    .=(-1)|^(0+1)*0 |^4 by A1
    .=(-1)|^(0+1)*0*(0+1)*(0|^2+0-1)/2 by NEWTON:11;
  then
A3: X[0];
  for n holds X[n] from NAT_1:sch 2(A3,A2);
  hence thesis;
end;
