reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th18:
  N is bounded iff [#]N is bounded
proof
  thus N is bounded implies [#]N is bounded
  proof
    assume N is bounded;
    then consider r such that
A1: 0<r and
A2: for x,y being Point of N holds dist(x,y)<=r;
    for x,y being Point of N st x in [#]N & y in [#]N holds dist(x,y ) <=
    r by A2;
    hence thesis by A1;
  end;
  assume [#]N is bounded;
  then consider r such that
A3: 0<r and
A4: for x,y being Point of N st x in [#]N & y in [#]N holds dist(x,y)<=r;
  take r;
  thus 0<r by A3;
  let x,y be Point of N;
  thus thesis by A4;
end;
