reserve X for non empty TopSpace;
reserve X for non empty TopSpace;
reserve X for non empty TopSpace,
  X0 for non empty maximal_Kolmogorov_subspace of X;

theorem Th18:
  for r being Function of X,X0 for M being Subset of X st M = the
  carrier of X0 holds (for a being Point of X holds M /\ MaxADSet(a) = {r.a})
  implies r is continuous Function of X,X0
proof
  let r be Function of X,X0;
  let M be Subset of X;
  assume
A1: M = the carrier of X0;
  reconsider N = M as Subset of X;
  assume
A2: for a being Point of X holds M /\ MaxADSet(a) = {r.a};
A3: N is maximal_T_0 by A1,Th11;
  then
A4: N is T_0;
  for F being Subset of X0 holds F is closed implies r" F is closed
  proof
    let F be Subset of X0;
    reconsider E = F as Subset of X by A1,XBOOLE_1:1;
    set R = {MaxADSet(a) where a is Point of X : a in E};
    now
      let x be object;
      assume
A5:   x in r" F;
      then reconsider b = x as Point of X;
A6:   r.b in F by A5,FUNCT_2:38;
      E c= the carrier of X;
      then reconsider a = r.b as Point of X by A6;
      MaxADSet(a) in R by A6;
      then
A7:   MaxADSet(a) c= union R by ZFMISC_1:74;
      M /\ MaxADSet(b) = {a} by A2;
      then a in M /\ MaxADSet(b) by ZFMISC_1:31;
      then a in MaxADSet(b) by XBOOLE_0:def 4;
      then
A8:   MaxADSet(a) = MaxADSet(b) by TEX_4:21;
A9:   {b} c= MaxADSet(b) by TEX_4:18;
      b in {b} by TARSKI:def 1;
      then b in MaxADSet(a) by A8,A9;
      hence x in union R by A7;
    end;
    then
A10: r" F c= union R by TARSKI:def 3;
    assume F is closed;
    then ex P being Subset of X st P is closed & P /\ [#]X0 = F by PRE_TOPC:13;
    then
A11: MaxADSet(E) is closed by A1,A3,Th5;
    now
      let C be set;
      assume C in R;
      then consider a being Point of X such that
A12:  C = MaxADSet(a) and
A13:  a in E;
      now
        let x be object;
        assume
A14:    x in C;
        then reconsider b = x as Point of X by A12;
A15:    M /\ MaxADSet(b) = {r.b} by A2;
A16:    M /\ MaxADSet(a) = {a} by A1,A4,A13;
        MaxADSet(a) = MaxADSet(b) by A12,A14,TEX_4:21;
        then a = r.x by A16,A15,ZFMISC_1:3;
        hence x in r" F by A12,A13,A14,FUNCT_2:38;
      end;
      hence C c= r" F by TARSKI:def 3;
    end;
    then
A17: union R c= r" F by ZFMISC_1:76;
    union R = MaxADSet(E) by TEX_4:def 11;
    hence thesis by A11,A17,A10,XBOOLE_0:def 10;
  end;
  hence thesis by PRE_TOPC:def 6;
end;
