reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem Th18:
  for R being complete LATTICE, N being net of R, p,q being Element of R
  st N is_eventually_in uparrow q holds lim_inf N >= q
proof
  let R be complete LATTICE, N be net of R, p,q be Element of R;
  assume N is_eventually_in uparrow q;
  then consider j0 being Element of N such that
A1: for i being Element of N st j0 <= i holds N.i in uparrow q;
  set X = the set of all "/\"({N.i where i is Element of N:
  i >= j},R) where j is Element of N;
  set Y = {N.i where i is Element of N: i >= j0};
  reconsider q9= q as Element of R;
  "/\"(Y,R) in X;
  then
A2: lim_inf N >= "/\"(Y,R) by YELLOW_2:22;
  q9 is_<=_than Y
  proof
    let y be Element of R;
    assume y in Y;
    then consider i1 being Element of N such that
A3: y = N.i1 and
A4: i1 >= j0;
    reconsider i19 = i1 as Element of N;
    N.i19 in uparrow q by A1,A4;
    hence q9 <= y by A3,WAYBEL_0:18;
  end;
  then "/\"(Y,R) >= q9 by YELLOW_0:33;
  hence thesis by A2,YELLOW_0:def 2;
end;
