
theorem Th18:
  for S, T being TopSpace, h being Function of S, T, g being
  Function of Omega S, Omega T st h = g & h is being_homeomorphism holds g is
  isomorphic
proof
  let S, T be TopSpace, h be Function of S, T, g be Function of Omega S, Omega
  T;
  assume that
A1: h = g and
A2: h is being_homeomorphism;
A3: dom h = [#]S by A2;
A4: rng h = [#]T by A2;
A5: the carrier of T = the carrier of Omega T by Lm1;
A6: the carrier of S = the carrier of Omega S by Lm1;
A7: h is one-to-one by A2;
  per cases;
  suppose
A8: S is non empty & T is non empty;
    then reconsider s = S, t = T as non empty TopSpace;
    reconsider f = g as Function of Omega s, Omega t;
    for x, y being Element of Omega s holds x <= y iff f.x <= f.y
    proof
      let x, y be Element of Omega s;
A9:   dom f = [#]S by A1,A2
        .= the carrier of S;
      reconsider Z = {f".(f.y)} as Subset of s by Lm1;
A10:  h" is being_homeomorphism by A2,A8,TOPS_2:56;
A11:   f is onto by A1,A4,A5,FUNCT_2:def 3;
      then
A12:   f" = f qua Function" by A1,A7,TOPS_2:def 4;
A13:  dom h = the carrier of Omega s by A3,Lm1;
      then
A14:  y = (h qua Function)".(h.y) by A7,FUNCT_1:34
        .= f".(f.y) by A11,A1,A7,TOPS_2:def 4;
      hereby
        reconsider Z = {f.y} as Subset of t by Lm1;
        assume x <= y;
        then consider Y being Subset of s such that
A15:    Y = {y} and
A16:    x in Cl Y by Def2;
A17:    Im(h,y) = Z by A1,A13,FUNCT_1:59;
        f.x in f.:Cl Y by A16,FUNCT_2:35;
        then h.x in Cl (h.:Y) by A1,A2,TOPS_2:60;
        hence f.x <= f.y by A1,A15,A17,Def2;
      end;
      assume f.x <= f.y;
      then consider Y being Subset of t such that
A18:  Y = {f.y} and
A19:  f.x in Cl Y by Def2;
A20:  f" = h" by A1,A5,A6;
A21:  x = f".(f.x) by A1,A7,A12,A13,FUNCT_1:34;
      f".(f.x) in f".:Cl Y by A19,FUNCT_2:35;
      then
A22:  h".(h.x) in Cl (h".:Y) by A1,A10,A20,TOPS_2:60;
      f".:Y = f"Y by A1,A7,A12,FUNCT_1:85
        .= Z by A1,A6,A7,A18,A14,A9,FINSEQ_5:4;
      hence thesis by A1,A20,A22,A21,A14,Def2;
    end;
    hence thesis by A1,A5,A7,A4,WAYBEL_0:66;
  end;
  suppose
    S is empty or T is empty;
    then reconsider s = S, t = T as empty TopSpace by A3,A4;
A23: Omega t is empty;
    Omega s is empty;
    hence thesis by A23,WAYBEL_0:def 38;
  end;
end;
