
theorem Th18:
  for W being with_non-empty_element set
  holds W LowerAdj" = W UpperAdj & W UpperAdj" = W LowerAdj
proof
  let W be with_non-empty_element set;
A1: ex x being non empty set st x in W by SETFAM_1:def 10;
  set B = W-SUP_category;
  set F = W LowerAdj, G = W UpperAdj;
A2: now
    let a be Object of B;
    thus F.(G.a) = latt (G.a) by Def6
      .= latt a by Def7
      .= a;
  end;
  now
    let a,b be Object of B;
    assume
A3: <^a,b^> <> {};
    then
A4: <^G.b, G.a^> <> {} by FUNCTOR0:def 19;
    let f be Morphism of a,b;
A5: G.f = UpperAdj @f by A3,Def7;
A6: @f = f by A3,YELLOW21:def 7;
A7: @(G.f) = G.f by A4,YELLOW21:def 7;
A8: G.a = latt a by Def7;
A9: G.b = latt b by Def7;
A10: @f is sups-preserving by A1,A3,A6,Def5;
    thus F.(G.f) = LowerAdj @(G.f) by A4,Def6
      .= f by A5,A6,A7,A8,A9,A10,Th11;
  end;
  hence F" = G by A2,YELLOW20:7;
  set B = W-INF_category;
  set G = W LowerAdj, F = W UpperAdj;
A11: now
    let a be Object of B;
    thus F.(G.a) = latt (G.a) by Def7
      .= latt a by Def6
      .= a;
  end;
  now
    let a,b be Object of B;
    assume
A12: <^a,b^> <> {};
    then
A13: <^G.b, G.a^> <> {} by FUNCTOR0:def 19;
    let f be Morphism of a,b;
A14: G.f = LowerAdj @f by A12,Def6;
A15: @f = f by A12,YELLOW21:def 7;
A16: @(G.f) = G.f by A13,YELLOW21:def 7;
A17: G.a = latt a by Def6;
A18: G.b = latt b by Def6;
A19: @f is infs-preserving by A1,A12,A15,Def4;
    thus F.(G.f) = UpperAdj @(G.f) by A13,Def7
      .= f by A14,A15,A16,A17,A18,A19,Th10;
  end;
  hence thesis by A11,YELLOW20:7;
end;
