reserve w, w1, w2 for Element of ExtREAL;
reserve c, c1, c2 for Complex;
reserve A, B, C, D for complex-membered set;
reserve F, G, H, I for ext-real-membered set;
reserve a, b, s, t, z for Complex;
reserve f, g, h, i, j for ExtReal;
reserve r for Real;
reserve e for set;

theorem Th199:
  a <> 0 implies a ** (A\B) = (a**A) \ (a**B)
proof
  assume
A1: a <> 0;
  let z;
  hereby
    assume z in a ** (A \ B);
    then consider c such that
A2: z = a*c and
A3: c in A\B by Th195;
A4: now
      assume a*c in a**B;
      then consider c1 such that
A5:   a*c = a*c1 and
A6:   c1 in B by Th195;
      c = c1 by A1,A5,XCMPLX_1:5;
      hence contradiction by A3,A6,XBOOLE_0:def 5;
    end;
    a*c in a**A by A3,Th193;
    hence z in (a**A) \ (a**B) by A2,A4,XBOOLE_0:def 5;
  end;
  assume
A7: z in (a**A) \ (a**B);
  then consider c such that
A8: z = a*c and
A9: c in A by Th195;
  now
    assume not c in A\B;
    then c in B by A9,XBOOLE_0:def 5;
    then a*c in a**B by Th193;
    hence contradiction by A7,A8,XBOOLE_0:def 5;
  end;
  hence thesis by A8,Th193;
end;
