reserve X for non empty UNITSTR;
reserve a, b for Real;
reserve x, y for Point of X;
reserve X for RealUnitarySpace;
reserve x, y, z, u, v for Point of X;

theorem Th19:
  |.x .|. y.| <= sqrt (x .|. x) * sqrt (y .|. y)
proof
A1: x <> 09(X) implies |.x .|. y.| <= sqrt (x .|. x) * sqrt (y .|. y)
  proof
A2: for t be Real holds x .|. x * t^2 + (2 * x .|. y) * t + y .|. y >= 0
    proof
      let t be Real;
      reconsider t as Real;
      (t * x + y) .|. (t * x + y) >= 0 by Def2;
      then (t * x) .|. (t * x) + 2 * (t * x) .|. y + y .|. y >= 0 by Th16;
      then t * x .|. (t * x) + 2 * (t * x) .|. y + y .|. y >= 0 by Def2;
      then t * ( t * x .|. x) + 2 * (t * x) .|. y + y .|. y >= 0 by Def2;
      then x .|. x * t^2 + 2 * (x .|. y * t) + y .|. y >= 0 by Def2;
      hence thesis;
    end;
A3: x .|. x >= 0 by Def2;
    assume x <> 09(X);
    then x .|. x <> 0 by Def2;
    then delta(x .|. x,(2 * x .|. y),y.|.y) <= 0 by A3,A2,QUIN_1:10;
    then (2 * x .|. y)^2 - 4 * x .|. x * y .|. y <= 0 by QUIN_1:def 1;
    then 4 * ((x .|. y)^2 - x .|. x * y .|. y) <= 0;
    then (x .|. y)^2 - x .|. x * y .|. y <= 0/4 by XREAL_1:77;
    then (x .|. y)^2 <= x .|. x * y .|. y by XREAL_1:50;
    then (|.x .|. y.|)^2 >= 0 & (|.x .|. y.|)^2 <= x .|. x * y .|. y by
COMPLEX1:75,XREAL_1:63;
    then sqrt (|.x .|. y.|)^2 <= sqrt (x .|. x * y .|. y) by SQUARE_1:26;
    then
A4: |.x .|. y.| <= sqrt (x .|. x * y .|. y) by COMPLEX1:46,SQUARE_1:22;
    y .|. y >= 0 by Def2;
    hence thesis by A3,A4,SQUARE_1:29;
  end;
  x = 09(X) implies |.x .|. y.| <= sqrt (x .|. x) * sqrt (y .|. y)
  proof
    assume x = 09(X);
    then x .|. y = 0 & sqrt (x .|. x) = 0 by Th14,SQUARE_1:17;
    hence thesis by ABSVALUE:2;
  end;
  hence thesis by A1;
end;
