reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  for z,u being Element of Y st G is independent & G={A,B,C,D} & A<>B &
  A<>C & A<>D & B<>C & B<>D & C<>D & EqClass(z,C '/\' D)=EqClass(u,C '/\' D)
  holds EqClass(u,CompF(A,G)) meets EqClass(z,CompF(B,G))
proof
  let z,u be Element of Y;
  assume that
A1: G is independent and
A2: G={A,B,C,D} and
A3: A<>B and
A4: A<>C & A<>D and
A5: B<>C & B<>D and
A6: C<>D and
A7: EqClass(z,C '/\' D)=EqClass(u,C '/\' D);
  set h = (B .--> EqClass(u,B)) +* (C .--> EqClass(u,C)) +* (D .--> EqClass(u,
  D)) +* (A .--> EqClass(z,A));
  set H=EqClass(z,CompF(B,G));
A8: A '/\' (C '/\' D) = A '/\' C '/\' D by PARTIT1:14;
A9: rng h = {h.A,h.B,h.C,h.D} by A2,Th17;
  rng h c= bool Y
  proof
    let t be object;
    assume
A10: t in rng h;
    per cases by A9,A10,ENUMSET1:def 2;
    suppose
      t=h.A;
      then t=EqClass(z,A) by FUNCT_7:94;
      hence thesis;
    end;
    suppose
      t=h.B;
      then t=EqClass(u,B) by A3,A4,A5,A6,Th15;
      hence thesis;
    end;
    suppose
      t=h.C;
      then t=EqClass(u,C) by A3,A4,A5,A6,Th15;
      hence thesis;
    end;
    suppose
      t=h.D;
      then t=EqClass(u,D) by A3,A4,A5,A6,Th15;
      hence thesis;
    end;
  end;
  then reconsider FF=rng h as Subset-Family of Y;
  set I=EqClass(z,A), GG=EqClass(u,B '/\' C '/\' D);
A11: GG = EqClass(u,B '/\' C) /\ EqClass(u,D) by Th1;
A12: for d being set st d in G holds h.d in d
  proof
    let d be set;
    assume
A13: d in G;
    per cases by A2,A13,ENUMSET1:def 2;
    suppose
A14:  d=A;
      h.A=EqClass(z,A) by FUNCT_7:94;
      hence thesis by A14;
    end;
    suppose
A15:  d=B;
      h.B=EqClass(u,B) by A3,A4,A5,A6,Th15;
      hence thesis by A15;
    end;
    suppose
A16:  d=C;
      h.C=EqClass(u,C) by A3,A4,A5,A6,Th15;
      hence thesis by A16;
    end;
    suppose
A17:  d=D;
      h.D=EqClass(u,D) by A3,A4,A5,A6,Th15;
      hence thesis by A17;
    end;
  end;
  dom h=G by A2,Th16;
  then (Intersect FF)<>{} by A1,A12,BVFUNC_2:def 5;
  then consider m being object such that
A18: m in Intersect FF by XBOOLE_0:def 1;
A19: dom h = G by A2,Th16;
  then A in dom h by A2,ENUMSET1:def 2;
  then
A20: h.A in rng h by FUNCT_1:def 3;
  then
A21: m in meet FF by A18,SETFAM_1:def 9;
  then
A22: h.A = EqClass(z,A) & m in h.A by A20,FUNCT_7:94,SETFAM_1:def 1;
  D in dom h by A2,A19,ENUMSET1:def 2;
  then h.D in rng h by FUNCT_1:def 3;
  then
A23: m in h.D by A21,SETFAM_1:def 1;
  C in dom h by A2,A19,ENUMSET1:def 2;
  then h.C in rng h by FUNCT_1:def 3;
  then
A24: m in h.C by A21,SETFAM_1:def 1;
  B in dom h by A2,A19,ENUMSET1:def 2;
  then h.B in rng h by FUNCT_1:def 3;
  then
A25: m in h.B by A21,SETFAM_1:def 1;
  h.B = EqClass(u,B) & h.C = EqClass(u,C) by A3,A4,A5,A6,Th15;
  then
A26: m in EqClass(u,B) /\ EqClass(u,C) by A25,A24,XBOOLE_0:def 4;
  h.D = EqClass(u,D) by A3,A4,A5,A6,Th15;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) by A23,A26,
XBOOLE_0:def 4;
  then m in EqClass(u,B) /\ EqClass(u,C) /\ EqClass(u,D) /\ EqClass(z,A) by A22
,XBOOLE_0:def 4;
  then GG /\ I <> {} by A11,Th1;
  then consider p being object such that
A27: p in GG /\ I by XBOOLE_0:def 1;
  reconsider p as Element of Y by A27;
  set K=EqClass(p,C '/\' D);
A28: p in GG by A27,XBOOLE_0:def 4;
  set L=EqClass(z,C '/\' D);
A29: z in I by EQREL_1:def 6;
  GG = EqClass(u,B '/\' (C '/\' D)) by PARTIT1:14;
  then
A30: GG c= EqClass(u,C '/\' D) by BVFUNC11:3;
  p in EqClass(p,C '/\' D) by EQREL_1:def 6;
  then K meets L by A7,A30,A28,XBOOLE_0:3;
  then K=L by EQREL_1:41;
  then z in K by EQREL_1:def 6;
  then
A31: z in I /\ K by A29,XBOOLE_0:def 4;
A32: p in K & p in I by A27,EQREL_1:def 6,XBOOLE_0:def 4;
  then p in I /\ K by XBOOLE_0:def 4;
  then I /\ K in INTERSECTION(A,C '/\' D) & not I /\ K in {{}} by
SETFAM_1:def 5,TARSKI:def 1;
  then
A33: I /\ K in INTERSECTION(A,C '/\' D) \ {{}} by XBOOLE_0:def 5;
  CompF(B,G) = A '/\' C '/\' D by A2,A3,A5,Th8;
  then I /\ K in CompF(B,G) by A33,A8,PARTIT1:def 4;
  then
A34: I /\ K = H or I /\ K misses H by EQREL_1:def 4;
  z in H by EQREL_1:def 6;
  then p in H by A32,A31,A34,XBOOLE_0:3,def 4;
  then p in GG /\ H by A28,XBOOLE_0:def 4;
  then GG meets H by XBOOLE_0:4;
  hence thesis by A2,A3,A4,Th7;
end;
