reserve IIG for monotonic Circuit-like non void non empty ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve s for State of SCS;
reserve iv for InputValues of SCS;
reserve IIG for finite monotonic Circuit-like non void non empty
  ManySortedSign;
reserve SCS for non-empty Circuit of IIG;
reserve InpFs for InputFuncs of SCS;
reserve s for State of SCS;
reserve iv for InputValues of SCS;

theorem
  commute InpFs is constant & InputVertices IIG is non empty implies for
  s1, s2 being State of SCS holds (Computation(s1,InpFs)).(depth SCS) = (
  Computation(s2,InpFs)).(depth SCS)
proof
  assume that
A1: commute InpFs is constant and
A2: InputVertices IIG is non empty;
  IIG is with_input_V by A2;
  then reconsider iv = (commute InpFs).0 as InputValues of SCS by CIRCUIT1:2;
  reconsider dSCS = depth SCS as Element of NAT by ORDINAL1:def 12;
  let s1, s2 be State of SCS;
  reconsider Cs1 = (Computation(s1,InpFs)).dSCS as State of SCS;
  reconsider Cs2 = (Computation(s2,InpFs)).dSCS as State of SCS;
  now
    thus the carrier of IIG = dom Cs1 by CIRCUIT1:3;
    thus the carrier of IIG = dom Cs2 by CIRCUIT1:3;
    let x be object;
    assume x in the carrier of IIG;
    then reconsider x9 = x as Vertex of IIG;
    Cs1.x9 = IGValue(x9,iv) by A1,A2,Th17;
    hence Cs1.x = Cs2.x by A1,A2,Th17;
  end;
  hence thesis;
end;
