reserve i, x, I for set,
  A, B, M for ManySortedSet of I,
  f, f1 for Function;
reserve SF, SG for SubsetFamily of M;
reserve E, T for Element of Bool M;

theorem Th19:
  i in dom |.{f,f1}.| implies |.{f,f1}.|.i = { f.i, f1.i }
proof
A1: f in {f,f1} & f1 in {f,f1} by TARSKI:def 2;
  consider A being non empty functional set such that
A2: A = {f,f1} and
  dom |.{f,f1}.| = meet the set of all  dom x where x is Element of A  and
A3: for i st i in dom |.{f,f1}.| holds |.{f,f1}.|.i = the set of all
 x.i where x is
  Element of A  by Def2;
  assume i in dom |.{f,f1}.|;
  then
A4: |.{f,f1}.|.i = the set of all  x.i where x is Element of A  by A3;
  thus |.{f,f1}.|.i c= { f.i, f1.i }
  proof
    let q be object;
    assume q in |.{f,f1}.|.i;
    then consider x being Element of A such that
A5: q = x.i by A4;
    per cases by A2,TARSKI:def 2;
    suppose
      x = f;
      hence thesis by A5,TARSKI:def 2;
    end;
    suppose
      x = f1;
      hence thesis by A5,TARSKI:def 2;
    end;
  end;
  let q be object;
  assume q in { f.i, f1.i };
  then q = f.i or q = f1.i by TARSKI:def 2;
  hence thesis by A2,A4,A1;
end;
