reserve A for QC-alphabet;
reserve i,j,k,l,m,n for Nat;
reserve a,b,e for set;
reserve t,u,v,w,z for QC-symbol of A;
reserve p,q,r,s for Element of CQC-WFF(A);
reserve x for Element of bound_QC-variables(A);
reserve ll for CQC-variable_list of k,A;
reserve P for QC-pred_symbol of k,A;
reserve f,h for Element of Funcs(bound_QC-variables(A),bound_QC-variables(A)),
  K,L for Element of Fin bound_QC-variables(A);

theorem Th19:
  for p being Element of QC-WFF(A) holds still_not-bound_in p is finite
proof
  defpred P[Element of QC-WFF(A)] means still_not-bound_in $1 is finite;
A1: for p being Element of QC-WFF(A) holds (p is atomic implies P[p]) &
P[VERUM(A)] & (p is negative & P[the_argument_of p] implies P[p]) &
(p is conjunctive & P[the_left_argument_of p] & P[the_right_argument_of p]
implies P[p]) & (p is universal & P[the_scope_of p] implies P[p])
  proof
    let p be Element of QC-WFF(A);
    thus p is atomic implies still_not-bound_in p is finite
    proof
      deffunc F(set) = (the_arguments_of p).$1;
      defpred B[Nat] means 1 <= $1 & $1 <= len the_arguments_of p;
      defpred A[Nat] means 1 <= $1 & $1 <= len the_arguments_of p &
      (the_arguments_of p).$1 in bound_QC-variables(A);
A2:   { F(k) : A[k] } c= { F(n) : B[n]}
      proof let e be object;
       assume e in { F(k) : A[k] };
        then ex k st e=F(k) & A[k];
       hence thesis;
      end;
      assume p is atomic;
      then still_not-bound_in p = still_not-bound_in the_arguments_of p by
QC_LANG3:4
        .= variables_in(the_arguments_of p,bound_QC-variables(A)) by QC_LANG3:2
        .= { (the_arguments_of p).k :
     1 <= k & k <= len the_arguments_of p &
      (the_arguments_of p).k in bound_QC-variables(A) };
      then still_not-bound_in p c= rng (the_arguments_of p) by A2,Th9;
      hence thesis;
    end;
    thus still_not-bound_in VERUM(A) is finite by QC_LANG3:3;
    thus p is negative & still_not-bound_in the_argument_of p is finite
    implies still_not-bound_in p is finite by QC_LANG3:6;
    thus p is conjunctive & still_not-bound_in the_left_argument_of p is
    finite & still_not-bound_in the_right_argument_of p is finite implies
    still_not-bound_in p is finite
    proof
      assume that
A3:   p is conjunctive and
A4:   still_not-bound_in the_left_argument_of p is finite and
A5:   still_not-bound_in the_right_argument_of p is finite;
      still_not-bound_in p = (still_not-bound_in the_left_argument_of p)
      \/ (still_not-bound_in the_right_argument_of p) by A3,QC_LANG3:9;
      hence thesis by A4,A5;
    end;
    assume that
A6: p is universal and
A7: still_not-bound_in the_scope_of p is finite;
    still_not-bound_in p = (still_not-bound_in the_scope_of p) \ {
    bound_in p} by A6,QC_LANG3:11;
    hence thesis by A7;
  end;
  thus for p being Element of QC-WFF(A) holds P[p] from QC_LANG1:sch 2(A1 );
end;
