reserve MS for OrtAfPl;
reserve MP for OrtAfSp;
reserve V for RealLinearSpace;
reserve w,y,u,v for VECTOR of V;

theorem Th19:
  Gen w,y & 0.V<>u & 0.V<>v & u,v are_Ort_wrt w,y implies ex c
being Real st for a,b being Real holds a*w+b*y,(c*b)*w+(-c*a)*y are_Ort_wrt w,y
  & (a*w+b*y)-u,((c*b)*w+(-c*a)*y)-v are_Ort_wrt w,y
proof
  assume that
A1: Gen w,y and
A2: 0.V<>u & 0.V<>v and
A3: u,v are_Ort_wrt w,y;
  consider a1,a2 being Real such that
A4: u=a1*w+a2*y by A1,ANALMETR:def 1;
  reconsider a1,a2 as Real;
  consider c being Real such that
  c <>0 and
A5: v=(c*a2)*w+(-c*a1)*y by A1,A2,A3,A4,Th18;
   reconsider c as Real;
  take c;
  let a,b be Real;
  set u9=a*w+b*y,v9=(c*b)*w+(-c*a)*y;
A6: pr1(w,y,u9)=a & pr2(w,y,u9)=b by A1,GEOMTRAP:def 4,def 5;
A7: pr1(w,y,v9) = c*b & pr2(w,y,v9) = -c*a by A1,GEOMTRAP:def 4,def 5;
  pr1(w,y,u)=a1 & pr2(w,y,u)=a2 by A1,A4,GEOMTRAP:def 4,def 5;
  then
A8: PProJ(w,y,u,v9) = a1*(c*b)+a2*(-c*a) by A7,GEOMTRAP:def 6;
  pr1(w,y,v)=c*a2 & pr2(w,y,v)=-c*a1 by A1,A5,GEOMTRAP:def 4,def 5;
  then
A9: PProJ(w,y,u9,v) = (c*a2)*a+(-c*a1)*b by A6,GEOMTRAP:def 6;
  thus a*w+b*y,(c*b)*w+(-c*a)*y are_Ort_wrt w,y by A1,Lm5;
  PProJ(w,y,(a*w+b*y)-u,((c*b)*w+(-c*a)*y)-v) = PProJ(w,y,u9-u,v9)-PProJ(
  w,y,u9-u,v) by A1,GEOMTRAP:30
    .= (PProJ(w,y,u9,v9)-PProJ(w,y,u,v9)) - PProJ(w,y,u9-u,v) by A1,GEOMTRAP:30
    .= (0 - PProJ(w,y,u,v9)) - PProJ(w,y,u9-u,v) by A1,Lm5
    .= (-PProJ(w,y,u,v9)) - (PProJ(w,y,u9,v) - PProJ(w,y,u,v)) by A1,
GEOMTRAP:30
    .= (-PProJ(w,y,u,v9)) - (PProJ(w,y,u9,v) - 0) by A1,A3,GEOMTRAP:32
    .= (-1)*(PProJ(w,y,u,v9) + PProJ(w,y,u9,v));
  hence thesis by A1,A8,A9,GEOMTRAP:32;
end;
