reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (ln*cosec) implies ln*cosec is_differentiable_on Z & for x st
  x in Z holds ((ln*cosec)`|Z).x = -cos.x/sin.x
proof
  assume
A1: Z c= dom (ln*cosec);
A2: for x st x in Z holds cosec.x>0
  proof
    let x;
    assume x in Z;
    then cosec.x in right_open_halfline(0) by A1,FUNCT_1:11,TAYLOR_1:18;
    then ex g being Real st cosec.x=g & 0<g by Lm1;
    hence thesis;
  end;
  dom (ln*cosec) c= dom cosec by RELAT_1:25;
  then
A3: Z c= dom cosec by A1,XBOOLE_1:1;
A4: for x st x in Z holds sin.x<>0
  proof
    let x;
    assume x in Z;
    then x in dom cosec by A1,FUNCT_1:11;
    hence thesis by RFUNCT_1:3;
  end;
A5: for x st x in Z holds cosec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.x<>0 by A4;
    hence thesis by Th2;
  end;
A6: for x st x in Z holds ln*cosec is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cosec is_differentiable_in x & cosec.x>0 by A2,A5;
    hence thesis by TAYLOR_1:20;
  end;
  then
A7: ln*cosec is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((ln*cosec)`|Z).x = -cos.x/sin.x
  proof
    let x;
    assume
A8: x in Z;
    then
A9: sin.x<>0 by A4;
    cosec is_differentiable_in x & cosec.x>0 by A2,A5,A8;
    then diff(ln*cosec,x) =diff(cosec,x)/(cosec.x) by TAYLOR_1:20
      .=(-cos.x/(sin.x)^2)/(cosec.x) by A9,Th2
      .=(-cos.x/(sin.x)^2)/(sin.x)" by A3,A8,RFUNCT_1:def 2
      .=((-cos.x)*sin.x)/(sin.x*sin.x)
      .=(-cos.x)/sin.x by A4,A8,XCMPLX_1:91;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A6,FDIFF_1:9;
end;
