reserve E, x, y, X for set;
reserve A, B, C, D for Subset of E^omega;
reserve a, a1, a2, b, c, c1, c2, d, ab, bc for Element of E^omega;
reserve e for Element of E;
reserve i, j, k, l, n, n1, n2, m for Nat;

theorem Th19:
  A ^^ (B /\ C) c= (A ^^ B) /\ (A ^^ C) & (B /\ C) ^^ A c= (B ^^ A
  ) /\ (C ^^ A)
proof
  thus A ^^ (B /\ C) c= (A ^^ B) /\ (A ^^ C)
  proof
    let x be object;
    assume x in A ^^ (B /\ C);
    then consider a, bc such that
A1: a in A and
A2: bc in B /\ C and
A3: x = a ^ bc by Def1;
    bc in C by A2,XBOOLE_0:def 4;
    then
A4: x in A ^^ C by A1,A3,Def1;
    bc in B by A2,XBOOLE_0:def 4;
    then x in A ^^ B by A1,A3,Def1;
    hence thesis by A4,XBOOLE_0:def 4;
  end;
  thus (B /\ C) ^^ A c= (B ^^ A) /\ (C ^^ A)
  proof
    let x be object;
    assume x in (B /\ C) ^^ A;
    then consider bc, a such that
A5: bc in B /\ C and
A6: a in A & x = bc ^ a by Def1;
    bc in C by A5,XBOOLE_0:def 4;
    then
A7: x in C ^^ A by A6,Def1;
    bc in B by A5,XBOOLE_0:def 4;
    then x in B ^^ A by A6,Def1;
    hence thesis by A7,XBOOLE_0:def 4;
  end;
end;
