
theorem Th19:
  for T being non empty TopStruct, A,B being Subset of T holds
  Cl_Seq(A) \/ Cl_Seq(B) = Cl_Seq(A \/ B)
proof
  let T be non empty TopStruct, A,B be Subset of T;
  thus Cl_Seq(A) \/ Cl_Seq(B) c= Cl_Seq(A \/ B)
  proof
    let x be object;
    assume
A1: x in Cl_Seq(A) \/ Cl_Seq(B);
    per cases by A1,XBOOLE_0:def 3;
    suppose
A2:   x in Cl_Seq(A);
      then reconsider x9=x as Point of T;
      consider S being sequence of T such that
A3:   rng S c= A and
A4:   x9 in Lim S by A2,Def1;
      A c= A \/ B by XBOOLE_1:7;
      then rng S c= A \/ B by A3;
      hence thesis by A4,Def1;
    end;
    suppose
A5:   x in Cl_Seq(B);
      then reconsider x9=x as Point of T;
      consider S being sequence of T such that
A6:   rng S c= B and
A7:   x9 in Lim S by A5,Def1;
      B c= A \/ B by XBOOLE_1:7;
      then rng S c= A \/ B by A6;
      hence thesis by A7,Def1;
    end;
  end;
  thus Cl_Seq(A \/ B) c= Cl_Seq(A) \/ Cl_Seq(B)
  proof
    let x be object;
    assume
A8: x in Cl_Seq(A \/ B);
    then reconsider x9 = x as Point of T;
    consider S being sequence of T such that
A9: rng S c= A \/ B and
A10: x9 in Lim S by A8,Def1;
    consider S1 being subsequence of S such that
A11: rng S1 c= A or rng S1 c= B by A9,Th4;
A12: Lim S c= Lim S1 by Th16;
    per cases by A11;
    suppose
      rng S1 c= A;
      then x9 in Cl_Seq(A) by A10,A12,Def1;
      hence thesis by XBOOLE_0:def 3;
    end;
    suppose
      rng S1 c= B;
      then x9 in Cl_Seq(B) by A10,A12,Def1;
      hence thesis by XBOOLE_0:def 3;
    end;
  end;
end;
