reserve x, y, X for set;
reserve E for non empty set;
reserve e for Element of E;
reserve u, u1, v, v1, v2, w, w9, w1, w2 for Element of E^omega;
reserve F for Subset of E^omega;
reserve i, k, l for Nat;
reserve TS for non empty transition-system over F;
reserve S, T for Subset of TS;
reserve SA for non empty semiautomaton over F;
reserve A for non empty automaton over F;
reserve p, q for Element of A;

theorem Th19:
  w in Lang(A) iff w-succ_of (the InitS of A, A) meets (the FinalS of A)
proof
  thus w in Lang(A) implies w-succ_of (the InitS of A, A) meets (the FinalS of
  A)
  proof
    assume w in Lang(A);
    then consider p, q such that
A1: p in the InitS of A and
A2: q in the FinalS of A and
A3: p, w ==>* q, A by Th18;
    q in w-succ_of (the InitS of A, A) by A1,A3,REWRITE3:103;
    hence thesis by A2,XBOOLE_0:3;
  end;
  assume w-succ_of (the InitS of A, A) meets (the FinalS of A);
  then consider x being object such that
A4: x in w-succ_of (the InitS of A, A) and
A5: x in (the FinalS of A) by XBOOLE_0:3;
  reconsider x as Element of A by A4;
  ex p st p in the InitS of A & p, w ==>* x, A by A4,REWRITE3:103;
  hence thesis by A5;
end;
