reserve A for non empty AltCatStr,
  B, C for non empty reflexive AltCatStr,
  F for feasible Covariant FunctorStr over A, B,
  G for feasible Covariant FunctorStr over B, C,
  M for feasible Contravariant FunctorStr over A, B,
  N for feasible Contravariant FunctorStr over B, C,
  o1, o2 for Object of A,
  m for Morphism of o1, o2;
reserve A, B, C, D for transitive with_units non empty AltCatStr,
  F1, F2, F3 for covariant Functor of A, B,
  G1, G2, G3 for covariant Functor of B, C,
  H1, H2 for covariant Functor of C, D,
  p for transformation of F1, F2,
  p1 for transformation of F2, F3,
  q for transformation of G1, G2,
  q1 for transformation of G2, G3,
  r for transformation of H1, H2;

theorem Th19:
  G1 * idt F1 = idt (G1*F1)
proof
  now
    let a be Object of A;
    thus (G1*(idt F1))!a = G1.((idt F1)!a) by Th11
      .= G1.(idm (F1.a)) by FUNCTOR2:4
      .= idm (G1.(F1.a)) by FUNCTOR2:1
      .= idm ((G1*F1).a) by FUNCTOR0:33
      .= (idt (G1*F1))!a by FUNCTOR2:4;
  end;
  hence thesis by FUNCTOR2:3;
end;
