reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;

theorem
  for k st 1 <= k & k+2 <= len f for j st 1 <= j & j+2 <= width GoB f &
f/.(k+1) = (GoB f)*(len GoB f,j+1) & (f/.k = (GoB f)*(len GoB f,j+2) & f/.(k+2)
= (GoB f)*(len GoB f -' 1,j+1) or f/.(k+2) = (GoB f)*(len GoB f,j+2) & f/.k = (
GoB f)*(len GoB f -' 1,j+1)) holds LSeg(1/2*((GoB f)*(len GoB f -' 1,j)+(GoB f)
*(len GoB f,j+1)), 1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))+|[1,0]|)
  misses L~f
proof
  let k such that
A1: k >= 1 and
A2: k+2 <= len f;
A3: k+1+1 = k+(1+1);
  then k+1 < len f by A2,NAT_1:13;
  then
A4: LSeg(f,k+1) c= L~f & LSeg(f,k) = LSeg(f/.k,f/.(k+1)) by A1,TOPREAL1:def 3
,TOPREAL3:19;
  1 <= k+1 by NAT_1:11;
  then
A5: LSeg(f,k+1) = LSeg(f/.(k+1),f/.(k+2)) by A2,A3,TOPREAL1:def 3;
  let j such that
A6: 1 <= j and
A7: j+2 <= width GoB f and
A8: f/.(k+1) = (GoB f)*(len GoB f,j+1) and
A9: f/.k = (GoB f)*(len GoB f,j+2) & f/.(k+2) = (GoB f)*(len GoB f -' 1,
j+1) or f/.(k+2) = (GoB f)*(len GoB f,j+2) & f/.k = (GoB f)*(len GoB f -' 1,j+1
  );
  j+1+1 = j+(1+1);
  then
A10: j+1 < width GoB f by A7,NAT_1:13;
  then
A11: j < width GoB f by NAT_1:13;
  then
A12: L~f misses Int cell(GoB f,len GoB f,j) by GOBOARD7:12;
  assume
A13: LSeg(1/2*((GoB f)*(len GoB f -' 1,j)+(GoB f)*(len GoB f,j+1)), 1/2*
  ((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))+|[1,0]|) meets L~f;
A14: 1 < len GoB f by GOBOARD7:32;
  then
A15: len GoB f -'1 +1 = len GoB f by XREAL_1:235;
  then
A16: len GoB f -' 1 < len GoB f by NAT_1:13;
  then L~f misses Int cell(GoB f,len GoB f -' 1,j) by A11,GOBOARD7:12;
  then
A17: L~f misses Int cell(GoB f,len GoB f -' 1,j) \/ Int cell(GoB f,len GoB f
  ,j) by A12,XBOOLE_1:70;
A18: 1 <= len GoB f -' 1 by A14,A15,NAT_1:13;
  then
  1/2*((GoB f)*(len GoB f -' 1,j)+(GoB f)*(len GoB f,j+1)) = 1/2*((GoB f)
  *(len GoB f -' 1,j+1)+(GoB f)*(len GoB f,j)) by A6,A15,A10,GOBOARD7:9;
  then
  L~f meets Int cell(GoB f,len GoB f -' 1,j) \/ Int cell(GoB f,len GoB f,
j) \/ { 1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1)) } by A6,A14,A11,A13
,GOBOARD6:69,XBOOLE_1:63;
  then L~f meets { 1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1)) } by A17
,XBOOLE_1:70;
  then consider k0 being Nat such that
  1 <= k0 and
  k0+1 <= len f and
A19: LSeg(f/.(k+1),(GoB f)*(len GoB f,j)) = LSeg(f,k0) by A6,A8,A14,A10,
GOBOARD7:39,ZFMISC_1:50;
  LSeg(f,k0) c= L~f & LSeg(f,k) c= L~f by TOPREAL3:19;
  hence contradiction by A6,A8,A9,A15,A18,A16,A10,A19,A4,A5,GOBOARD7:60;
end;
