reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem Th19:
  integral(( #Z n*sin)(#)cos,A) = ((1/(n+1))(#)( #Z (n+1)*sin)).(
  upper_bound A) -((1/(n+1))(#)( #Z (n+1)*sin)).(lower_bound A)
proof
A1: [#]REAL = dom (( #Z n*sin)(#)cos) by FUNCT_2:def 1;
A2: for x being Element of REAL
st x in dom (((1/(n+1))(#)( #Z (n+1)*sin))`|REAL) holds (((1/(n+1)
  )(#)( #Z (n+1)*sin))`|REAL).x = (( #Z n*sin)(#)cos).x
  proof
    let x be Element of REAL;
    assume x in dom (((1/(n+1))(#)( #Z (n+1)*sin))`|REAL);
    (((1/(n+1))(#)( #Z (n+1)*sin))`|REAL).x =(sin.x) #Z n *cos.x by Th3
      .=( #Z n).(sin.x)*cos.x by TAYLOR_1:def 1
      .=(( #Zn)*sin).x*cos.x by FUNCT_1:13,SIN_COS:24
      .= ((( #Z n)*sin)(#)cos).x by A1,VALUED_1:def 4;
    hence thesis;
  end;
  #Z n*sin is_differentiable_in x0
  proof
    sin is_differentiable_in x0 by SIN_COS:64;
    hence thesis by TAYLOR_1:3;
  end;
  then dom ( #Z n*sin)=REAL & for x0 st x0 in REAL holds #Z n*sin
  is_differentiable_in x0 by FUNCT_2:def 1;
  then #Z n*sin is_differentiable_on REAL by A1,FDIFF_1:9;
  then
A3: (( #Z n*sin)(#)cos)|REAL is continuous by A1,FDIFF_1:21,25,SIN_COS:67;
  then (( #Z n*sin)(#)cos)|A is continuous by FCONT_1:16;
  then
A4: ( #Z n)*sin(#)cos is_integrable_on A by A1,INTEGRA5:11;
  (1/(n+1))(#)( #Z (n+1)*sin) is_differentiable_on REAL by Th3;
  then dom (((1/(n+1))(#)( #Z (n+1)*sin))`|REAL) = dom (( #Z n*sin)(#)cos) by
A1,FDIFF_1:def 7;
  then
A5: (((1/(n+1))(#)( #Z (n+1)*sin))`|REAL) = (( #Z n*sin)(#)cos) by A2,
PARTFUN1:5;
  (( #Z n)*sin(#)cos)|A is bounded by A1,A3,INTEGRA5:10;
  hence thesis by A4,A5,Th3,INTEGRA5:13;
end;
