reserve n for Nat;

theorem
  for C be compact connected non vertical non horizontal Subset of
TOP-REAL 2 for i,j,k be Nat st 1 <= j & j <= k & k <= len Gauge(C,n)
  & 1 <= i & i <= width Gauge(C,n) & Gauge(C,n)*(k,i) in L~Lower_Seq(C,n) ex k1
be Nat st j <= k1 & k1 <= k & LSeg(Gauge(C,n)*(j,i),Gauge(C,n)*(k1,i
  )) /\ L~Lower_Seq(C,n) = {Gauge(C,n)*(k1,i)}
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  let i,j,k be Nat;
  assume that
A1: 1 <= j and
A2: j <= k and
A3: k <= len Gauge(C,n) and
A4: 1 <= i and
A5: i <= width Gauge(C,n) and
A6: Gauge(C,n)*(k,i) in L~Lower_Seq(C,n);
  set G = Gauge(C,n);
A7: k >= 1 by A1,A2,XXREAL_0:2;
  then
A8: [k,i] in Indices G by A3,A4,A5,MATRIX_0:30;
  set X = LSeg(G*(j,i),G*(k,i)) /\ L~Lower_Seq(C,n);
A9: G*(k,i) in LSeg(G*(j,i),G*(k,i)) by RLTOPSP1:68;
  then reconsider X1=X as non empty compact Subset of TOP-REAL 2 by A6,
XBOOLE_0:def 4;
A10: LSeg(G*(j,i),G*(k,i)) meets L~Lower_Seq(C,n) by A6,A9,XBOOLE_0:3;
  set s = G*(1,i)`2;
  set e = G*(k,i);
  set f = G*(j,i);
  set w1 = lower_bound(proj1.:(LSeg(f,e) /\ L~Lower_Seq(C,n)));
A11: len G = width G by JORDAN8:def 1;
  then
A12: j <= width G by A2,A3,XXREAL_0:2;
  then [j,i] in Indices G by A1,A4,A5,A11,MATRIX_0:30;
  then consider k1 be Nat such that
A13: j <= k1 and
A14: k1 <= k and
A15: G*(k1,i)`1 = w1 by A2,A10,A8,JORDAN1F:3,JORDAN1G:5;
  set p = |[w1,s]|;
A16: k1 <= width G by A3,A11,A14,XXREAL_0:2;
  f`2 = s by A1,A4,A5,A11,A12,GOBOARD5:1
    .= e`2 by A3,A4,A5,A7,GOBOARD5:1;
  then
A17: LSeg(f,e) is horizontal by SPPOL_1:15;
  take k1;
  thus j <= k1 & k1 <= k by A13,A14;
  consider pp be object such that
A18: pp in W-most X1 by XBOOLE_0:def 1;
A19: 1 <= k1 by A1,A13,XXREAL_0:2;
  then
A20: G*(k1,i)`2 = s by A4,A5,A11,A16,GOBOARD5:1;
  then
A21: p = G*(k1,i) by A15,EUCLID:53;
  then
A22: f`1 <= p`1 by A1,A4,A5,A11,A13,A16,SPRECT_3:13;
A23: f`2 = p`2 by A1,A4,A5,A11,A12,A20,A21,GOBOARD5:1;
  reconsider pp as Point of TOP-REAL 2 by A18;
A24: pp in X by A18,XBOOLE_0:def 4;
  then
A25: pp in L~Lower_Seq(C,n) by XBOOLE_0:def 4;
A26: p`1 = W-bound X by A15,A21,SPRECT_1:43
    .= (W-min X)`1 by EUCLID:52
    .= pp`1 by A18,PSCOMP_1:31;
  pp in LSeg(G*(j,i),G*(k,i)) by A24,XBOOLE_0:def 4;
  then pp`2 = p`2 by A23,A17,SPPOL_1:40;
  then
A27: p in L~Lower_Seq(C,n) by A25,A26,TOPREAL3:6;
  for x be object holds x in LSeg(p,f) /\ L~Lower_Seq(C,n) iff x = p
  proof
    let x be object;
    thus x in LSeg(p,f) /\ L~Lower_Seq(C,n) implies x = p
    proof
      reconsider EE = LSeg(f,e) /\ L~Lower_Seq(C,n) as compact Subset of
      TOP-REAL 2;
      assume
A28:  x in LSeg(p,f) /\ L~Lower_Seq(C,n);
      then reconsider pp = x as Point of TOP-REAL 2;
A29:  pp in LSeg(p,f) by A28,XBOOLE_0:def 4;
      then
A30:  pp`1 <= p`1 by A22,TOPREAL1:3;
A31:  p`1 <= e`1 by A3,A4,A5,A14,A19,A21,SPRECT_3:13;
A32:  f`1 <= p`1 by A1,A4,A5,A11,A13,A16,A21,SPRECT_3:13;
A33:  e`2 = p`2 by A3,A4,A5,A7,A20,A21,GOBOARD5:1;
      reconsider E0 = proj1.:EE as compact Subset of REAL by Th4;
A34:  f in LSeg(f,e) by RLTOPSP1:68;
      f`2 = p`2 by A1,A4,A5,A11,A12,A20,A21,GOBOARD5:1;
      then p in LSeg(f,e) by A33,A32,A31,GOBOARD7:8;
      then
A35:  LSeg(p,f) c= LSeg(f,e) by A34,TOPREAL1:6;
      pp in L~Lower_Seq(C,n) by A28,XBOOLE_0:def 4;
      then pp in EE by A29,A35,XBOOLE_0:def 4;
      then proj1.pp in E0 by FUNCT_2:35;
      then
A36:  pp`1 in E0 by PSCOMP_1:def 5;
      E0 is real-bounded by RCOMP_1:10;
      then E0 is bounded_below by XXREAL_2:def 11;
      then p`1 <= pp`1 by A15,A21,A36,SEQ_4:def 2;
      then
A37:  pp`1 = p`1 by A30,XXREAL_0:1;
      pp`2 = p`2 by A23,A29,GOBOARD7:6;
      hence thesis by A37,TOPREAL3:6;
    end;
    assume
A38: x = p;
    then x in LSeg(p,f) by RLTOPSP1:68;
    hence thesis by A27,A38,XBOOLE_0:def 4;
  end;
  hence thesis by A21,TARSKI:def 1;
end;
