reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem
  for s being Real holds abs <*s*>=<*|.s.|*>
proof
  let s be Real;
   reconsider s as Element of REAL by XREAL_0:def 1;
  rng <*s*> c= dom absreal
  proof
    let x be object;
    assume x in rng <*s*>;
    then x in {s} by FINSEQ_1:38;
    then
A1: x=s by TARSKI:def 1;
    dom absreal =REAL by FUNCT_2:def 1;
    hence thesis by A1;
  end;
  then dom <*s*>=dom (absreal*<*s*>) by RELAT_1:27;
  then Seg 1=dom (abs <*s*>) by FINSEQ_1:def 8;
  then
A2: len (abs <*s*>)=1 by FINSEQ_1:def 3;
A3: len <*|.s.|*>=1 by FINSEQ_1:39;
  for j be Nat st 1<=j & j<=len <*|.s.|*> holds <*|.s.|*>.j=(abs <*s*>) .j
  proof
    let j be Nat;
A4: <*s*>.1=s & <*s*> is Element of REAL 1 by FINSEQ_2:98;
    assume 1<=j & j<=len <*|.s.|*>;
    then
A5: j=1 by A3,XXREAL_0:1;
    thus thesis by A5,A4,VALUED_1:18;
  end;
  hence thesis by A2,A3,FINSEQ_1:14;
end;
