
theorem :: theorem 3.1 (vi)
  for R, S being antisymmetric reflexive transitive with_suprema non
  empty RelStr for x, y being Element of R, a, b being Element of S st (the
  carrier of R) /\ (the carrier of S) is lower directed Subset of S & (the
carrier of R) /\ (the carrier of S) is upper Subset of R & R tolerates S & x =
  a & y = b holds x "\/" y = a "\/" b
proof
  let R, S be antisymmetric reflexive transitive with_suprema non empty
  RelStr;
  let x, y be Element of R;
  let a, b be Element of S;
  assume that
A1: (the carrier of R) /\ (the carrier of S) is lower directed Subset of S and
A2: (the carrier of R) /\ (the carrier of S) is upper Subset of R and
A3: R tolerates S and
A4: x = a and
A5: y = b;
  a in (the carrier of R) /\ (the carrier of S) & b in (the carrier of R)
  /\ ( the carrier of S) by A4,A5,XBOOLE_0:def 4;
  then reconsider xy = a "\/" b as Element of R by A1,Th13,Th16;
  a "\/" b >= b by YELLOW_0:22;
  then
A6: xy >= y by A3,A5,Th15;
A7: for d being Element of R st d >= x & d >= y holds xy <= d
  proof
    let d be Element of R;
    reconsider X = x, D = d as Element of R [*] S by Th10;
    assume that
A8: d >= x and
A9: d >= y;
    X <= D by A3,A8,Th8;
    then reconsider dd = d as Element of S by A2,A4,Th18;
    dd >= a & b <= dd by A3,A4,A5,A8,A9,Th15;
    then a "\/" b <= dd by YELLOW_5:9;
    hence thesis by A3,Th15;
  end;
  a "\/" b >= a by YELLOW_0:22;
  then xy >= x by A3,A4,Th15;
  hence thesis by A6,A7,YELLOW_0:22;
end;
