
theorem Th20:
  for X,Y be RealNormSpace,
      f be object
  holds
    f is LinearOperator of product <*X*>,Y
    iff f is MultilinearOperator of <*X*>,Y
  proof
    let X,Y be RealNormSpace,
        f be object;

    A1: dom <*X*> = {1} by FINSEQ_1:2,38;

    hereby
      assume f is LinearOperator of product <*X*>,Y; then
      reconsider f0 = f as LinearOperator of product <*X*>,Y;

      for i be Element of dom <*X*>,
          s be Element of product <*X*>
      holds f0 * reproj(i,s) is LinearOperator of <*X*>.i,Y
      proof
        let i be Element of dom <*X*>,
            s be Element of product <*X*>;
        A2: i = 1 by A1,TARSKI:def 1; then
        A3: <*X*>.i = X;

        for x be Element of X holds (reproj(i,s)).x = (IsoCPNrSP X).x
        proof
          let x be Element of X;

          s in the carrier of product <*X*>; then
          s in rng(IsoCPNrSP X) by FUNCT_2:def 3; then
          consider x0 be object such that
          A4: x0 in the carrier of X
            & s = (IsoCPNrSP X).x0 by FUNCT_2:11;
          reconsider x0 as Point of X by A4;
          A5: (IsoCPNrSP X).x0 = <*x0*> by Def2;
          A6: dom s = Seg 1 by A4,A5,FINSEQ_1:38;

          dom(s +* (i,x))
           = dom s by FUNCT_7:30
          .= Seg 1 by A4,A5,FINSEQ_1:38; then
          A7: len(s +* (i,x)) = 1 by FINSEQ_1:def 3;
          A8: (s +* (i,x)).1 = x by A1,A2,A6,FINSEQ_1:2,FUNCT_7:31;

          thus
          (reproj(i,s)).x
           = s +* (i,x) by A3,NDIFF_5:def 4
          .= <*x*> by A7,A8,FINSEQ_1:40
          .= (IsoCPNrSP X).x by Def2;
        end; then
        reproj(i,s) = IsoCPNrSP(X) by A3;

        hence f0 * reproj(i,s) is LinearOperator of <*X*>.i,Y by A3,Th16;
      end;
      hence f is MultilinearOperator of <*X*>,Y by LOPBAN10:def 6;
    end;
    assume f is MultilinearOperator of <*X*>,Y; then
    reconsider f0 = f as MultilinearOperator of <*X*>,Y;
    reconsider i = 1 as Element of dom <*X*> by A1,TARSKI:def 1;
    set s = the Element of product <*X*>;
    A9: reproj(i,s) = IsoCPNrSP(X) by Th18;
    f0 * reproj(i,s) is LinearOperator of X,Y by LOPBAN10:def 6;
    hence f is LinearOperator of product <*X*>,Y by A9,Th16;
  end;
