
theorem Th19:
  for X be RealNormSpace for seq be sequence of X for z be Real
  holds Partial_Sums(z * seq) = z * Partial_Sums(seq)
proof
  let X be RealNormSpace;
  let seq be sequence of X;
  let z be Real;
  defpred P[Nat] means
Partial_Sums(z * seq).$1 = (z * Partial_Sums
  (seq)).$1;
A1: now
    let n be Nat;
    assume
A2: P[n];
    Partial_Sums(z * seq).(n+1) =Partial_Sums(z * seq).n + (z * seq).(n+1)
    by BHSP_4:def 1
      .=(z * Partial_Sums(seq).n )+ (z * seq).(n+1) by A2,NORMSP_1:def 5
      .=(z * Partial_Sums(seq).n )+ (z * seq.(n+1)) by NORMSP_1:def 5
      .= z * ( Partial_Sums(seq).n + seq.(n+1)) by RLVECT_1:def 5
      .= z * ( Partial_Sums(seq).(n+1)) by BHSP_4:def 1
      .= (z * Partial_Sums(seq)).(n+1) by NORMSP_1:def 5;
    hence P[n+1];
  end;
  Partial_Sums(z * seq).0 = (z * seq).0 by BHSP_4:def 1
    .=z * seq.0 by NORMSP_1:def 5
    .=z * Partial_Sums(seq).0 by BHSP_4:def 1
    .=(z * Partial_Sums(seq)).0 by NORMSP_1:def 5;
  then
A3: P[0];
  for n be Nat holds P[n] from NAT_1:sch 2(A3,A1);
   then for n be Element of NAT holds P[n];
  hence thesis by FUNCT_2:63;
end;
