reserve a,b,r for Real;
reserve A,B for non empty set;
reserve f,g,h for Element of PFuncs(A,REAL);

theorem Th19:
  (addpfunc A).((multrealpfunc A).(a,f),(multrealpfunc A).(b,f)) =
  (multrealpfunc A).(a+b,f)
proof
  reconsider aa=a, bb=b as Element of REAL by XREAL_0:def 1;
  reconsider g = (multrealpfunc A).(aa,f) as Element of PFuncs(A,REAL);
  reconsider h = (multrealpfunc A).(bb,f) as Element of PFuncs(A,REAL);
  reconsider k = (multrealpfunc A).(aa+bb,f) as Element of PFuncs(A,REAL);
  set j = (addpfunc A).(g,h);
  dom g = dom f by Th9;
  then dom h /\ dom g = dom f /\ dom f by Th9;
  then
A1: dom j = dom f by Th6;
A2: now
    let x be Element of A;
    assume
A3: x in dom j;
    then x in dom(b(#)f) by A1,VALUED_1:def 5;
    then (b(#)f).x = b*f.x by VALUED_1:def 5;
    then
A4: h.x = b*f.x by Def4;
    x in dom(a(#)f) by A1,A3,VALUED_1:def 5;
    then (a(#)f).x = a*f.x by VALUED_1:def 5;
    then g.x = a*f.x by Def4;
    then g.x + h.x = (a+b)*(f.x) by A4;
    hence j.x = (a+b)*(f.x) by A3,Th6
      .= k.x by A1,A3,Th9;
  end;
  dom k = dom f by Th9;
  hence thesis by A1,A2,PARTFUN1:5;
end;
