reserve x, y for object, X for set,
  i, j, k, l, n, m for Nat,
  D for non empty set,
  K for commutative Ring,
  a,b for Element of K,
  perm, p, q for Element of Permutations(n),
  Perm,P for Permutation of Seg n,
  F for Function of Seg n,Seg n,
  perm2, p2, q2, pq2 for Element of Permutations(n+2),
  Perm2 for Permutation of Seg (n+2);
reserve s for Element of 2Set Seg (n+2);

theorem Th19:
  for p,q be (Permutation of X),p1,q1 be Permutation of X\/{x} st
p1|X = p & q1|X = q & p1.x = x & q1.x = x holds (p1*q1) |X = p*q &
(p1*q1).x = x
proof
  let p,q be Permutation of X,p1,q1 be Permutation of X\/{x} such that
A1: p1|X=p and
A2: q1|X=q and
A3: p1.x=x and
A4: q1.x=x;
  set pq=p*q;
  set pq1=p1*q1;
  set X1=X\/{x};
A5: X c=X1 by XBOOLE_1:7;
A6: rng q=X by FUNCT_2:def 3;
A7: dom q=X by FUNCT_2:52;
  dom pq1=X1 by FUNCT_2:52;
  then
A8: dom (pq1|X)=X by RELAT_1:62,XBOOLE_1:7;
A9: dom pq =X by FUNCT_2:52;
A10: dom p=X by FUNCT_2:52;
  for y be object st y in dom pq holds pq.y=(pq1|X).y
  proof
    let y be object such that
A11: y in dom pq;
A12: pq.y=p.(q.y) by A9,A11,FUNCT_2:15;
A13: pq1.y=(pq1|X).y by A9,A8,A11,FUNCT_1:47;
A14: q.y in rng q by A7,A9,A11,FUNCT_1:def 3;
A15: pq1.y=p1.(q1.y) by A5,A9,A11,FUNCT_2:15;
    q1.y=q.y by A2,A7,A9,A11,FUNCT_1:47;
    hence thesis by A1,A10,A6,A14,A13,A12,A15,FUNCT_1:47;
  end;
  hence pq1|X = pq by A8,FUNCT_1:2,FUNCT_2:52;
  x in {x} by TARSKI:def 1;
  then x in X1 by XBOOLE_0:def 3;
  hence thesis by A3,A4,FUNCT_2:15;
end;
