reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th19:
  i in dom b1 implies b1/.i|-- b1 = Line(1.(K,len b1),i)
proof
  set ONE=1.(K,len b1);
  set bb=b1/.i|-- b1;
  consider KL be Linear_Combination of V1 such that
A1: b1/.i = Sum(KL) & Carrier KL c= rng b1 and
A2: for k st 1<=k & k<=len bb holds bb/.k=KL.(b1/.k) by MATRLIN:def 7;
  reconsider rb1=rng b1 as Basis of V1 by MATRLIN:def 2;
A3: rb1 is linearly-independent by VECTSP_7:def 3;
  b1/.i in {b1/.i} by TARSKI:def 1;
  then b1/.i in Lin{b1/.i} by VECTSP_7:8;
  then consider Lb be Linear_Combination of {b1/.i} such that
A4: b1/.i=Sum Lb by VECTSP_7:7;
  assume
A5: i in dom b1;
  then
A6: b1.i=b1/.i by PARTFUN1:def 6;
  then
A7: Carrier Lb c= {b1.i} by VECTSP_6:def 4;
A8: b1.i in rb1 by A5,FUNCT_1:def 3;
  then {b1.i}c= rb1 by ZFMISC_1:31;
  then Carrier Lb c= rb1 by A7;
  then
A9: Lb = KL by A4,A1,A3,MATRLIN:5;
A10: width ONE=len b1 by MATRIX_0:24;
A11: Indices ONE=[:Seg len b1,Seg len b1:] by MATRIX_0:24;
A12: len b1=len bb by MATRLIN:def 7;
A13: b1/.i<>0.V1 by A6,A3,A8,VECTSP_7:2;
A14: now
    let j such that
A15: 1<=j & j<=len bb;
A16: j in Seg len b1 by A12,A15;
    i in Seg len b1 by A5,FINSEQ_1:def 3;
    then
A17: [i,j] in Indices ONE by A11,A16,ZFMISC_1:87;
A18: j in dom b1 by A12,A15,FINSEQ_3:25;
A19: dom bb=dom b1 by A12,FINSEQ_3:29;
    now
      per cases;
      suppose
A20:    i=j;
        Lb.(b1/.i) *(b1/.i) = b1/.i by A4,VECTSP_6:17
          .= 1_K*(b1/.i);
        then
A21:    1_K = KL.(b1/.i) by A13,A9,VECTSP10:4
          .= bb/.j by A2,A15,A20;
        1_K = ONE*(i,j) by A17,A20,MATRIX_1:def 3
          .= Line(ONE,i).j by A10,A16,MATRIX_0:def 7;
        hence Line(ONE,i).j=bb.j by A18,A19,A21,PARTFUN1:def 6;
      end;
      suppose
A22:    i<>j;
        b1 is one-to-one by MATRLIN:def 2;
        then b1.i <> b1.j by A5,A18,A22;
        then
A23:    not b1.j in Carrier Lb by A7,TARSKI:def 1;
A24:    0.K = ONE*(i,j) by A17,A22,MATRIX_1:def 3
          .= Line(ONE,i).j by A10,A16,MATRIX_0:def 7;
        b1.j = b1/.j by A18,PARTFUN1:def 6;
        then 0.K = KL.(b1/.j) by A9,A23
          .= bb/.j by A2,A15;
        hence Line(ONE,i).j=bb.j by A18,A19,A24,PARTFUN1:def 6;
      end;
    end;
    hence Line(ONE,i).j=bb.j;
  end;
  len Line(ONE,i)=len b1 by A10,CARD_1:def 7;
  hence thesis by A12,A14;
end;
