reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th19:
  D c= dom(F.0) & (for n be Nat holds G.n = (F.n)|D) & (for x be
  Element of X st x in D holds F#x is convergent) implies (lim F)|D = lim G
proof
  assume that
A1: D c= dom(F.0) and
A2: for n be Nat holds G.n = (F.n)|D and
A3: for x be Element of X st x in D holds F#x is convergent;
  G.0 = (F.0)|D by A2;
  then
A4: dom(G.0) = D by A1,RELAT_1:62;
A5: dom((lim F)|D) = dom(lim F) /\ D by RELAT_1:61;
  then dom((lim F)|D) = dom(F.0) /\ D by MESFUNC8:def 9;
  then dom((lim F)|D) = D by A1,XBOOLE_1:28;
  then
A6: dom((lim F)|D) = dom(lim G) by A4,MESFUNC8:def 9;
  now
    let x be Element of X;
    assume
A7: x in dom((lim F)|D);
    then
A8: ((lim F)|D).x = (lim F).x by FUNCT_1:47;
    x in dom(lim F) by A5,A7,XBOOLE_0:def 4;
    then
A9: ((lim F)|D).x = lim(F#x) by A8,MESFUNC8:def 9;
A10: x in D by A7,RELAT_1:57;
    then
A11: F#x is convergent by A3;
    per cases by A11;
    suppose
A12:  F#x is convergent_to_+infty;
      then G#x is convergent_to_+infty by A2,A10,Th12;
      then lim(G#x) = +infty by Th7;
      then (lim G).x = +infty by A6,A7,MESFUNC8:def 9;
      hence (lim G).x = ((lim F)|D).x by A9,A12,Th7;
    end;
    suppose
A13:  F#x is convergent_to_-infty;
      then G#x is convergent_to_-infty by A2,A10,Th12;
      then lim(G#x) = -infty by Th7;
      then (lim G).x = -infty by A6,A7,MESFUNC8:def 9;
      hence (lim G).x = ((lim F)|D).x by A9,A13,Th7;
    end;
    suppose
A14:  F#x is convergent_to_finite_number;
      then consider g be Real such that
A15:  lim(F#x) = g and
A16:  for p be Real st 0<p ex n be Nat st for m be Nat st n<=m
      holds |. (F#x).m - lim(F#x) .| < p by Th7;
A17:  now
        let p be Real;
        assume 0 < p;
        then consider n be Nat such that
A18:    for m be Nat st n <= m holds |. (F#x).m - lim(F#x) .| < p by A16;
        take n;
        let m be Nat;
        (F#x).m = (F.m).x by MESFUNC5:def 13;
        then (F#x).m = ((F.m)|D).x by A10,FUNCT_1:49;
        then
A19:    (F#x).m = (G.m).x by A2;
        assume n <= m;
        then |. (F#x).m - lim(F#x) .| < p by A18;
        hence |. (G#x).m -  g .| < p by A15,A19,MESFUNC5:def 13;
      end;
      reconsider g as R_eal by XXREAL_0:def 1;
A20:  G#x is convergent_to_finite_number by A2,A10,A14,Th12;
      then G#x is convergent;
      then lim(G#x) = g by A17,A20,MESFUNC5:def 12;
      hence (lim G).x = ((lim F)|D).x by A6,A7,A9,A15,MESFUNC8:def 9;
    end;
  end;
  hence thesis by A6,PARTFUN1:5;
end;
