reserve n,i,j,k,l for Nat;
reserve D for non empty set;
reserve c,d for Element of D;
reserve p,q,q9,r for FinSequence of D;
reserve RAS for MidSp-like non empty ReperAlgebraStr over n+2;
reserve a,b,d,pii,p9i for Point of RAS;
reserve p,q for Tuple of (n+1),RAS;
reserve m for Nat of n;
reserve W for ATLAS of RAS;
reserve v for Vector of W;
reserve x,y for Tuple of (n+1),W;

theorem Th19:
  RAS is being_invariance iff for a,b,x holds Phi(a,x) = Phi(b,x)
proof
A1: (for a,b,x holds Phi(a,x) = Phi(b,x)) implies RAS is being_invariance
  proof
    assume
A2: for a,b,x holds Phi(a,x) = Phi(b,x);
    let a,b,p,q;
A3: W.(a,*'(a,(a,W.(a,p)).W)) = Phi(a,W.(a,p)) .= Phi(b,W.(a,p)) by A2
      .= W.(b,*'(b,(b,W.(a,p)).W));
    assume
A4: for m holds a@(q.m) = b@(p.m);
A5: now
      let m;
      a@(q.m) = b@(p.m) by A4;
      then
A6:   W.(a,p.m) = W.(b,q.m) by MIDSP_2:33;
      thus W.(a,p).m = W.(a,p.m) by Def9
        .= W.(b,q).m by A6,Def9;
    end;
    W.(a,*'(a,p)) = W.(a,*'(a,(a,W.(a,p)).W)) by Th15
      .= W.(b,*'(b,(b,W.(b,q)).W)) by A5,A3,Th14
      .= W.(b,*'(b,q)) by Th15;
    hence thesis by MIDSP_2:33;
  end;
  now
    assume
A7: RAS is being_invariance;
    let a,b,x;
    set p = (a,x).W, q = (b,x).W;
A8: W.(a,p) = x by Th15
      .= W.(b,q) by Th15;
    now
      let m;
      W.(a,p.m) = W.(a,p).m by Def9
        .= W.(b,q.m) by A8,Def9;
      hence a@(q.m) = b@(p.m) by MIDSP_2:33;
    end;
    then a@*'(b,q) = b@*'(a,p) by A7;
    hence Phi(a,x) = Phi(b,x) by MIDSP_2:33;
  end;
  hence thesis by A1;
end;
