reserve A,B,a,b,c,d,e,f,g,h for set;

theorem
  for G being RelStr, H being full SubRelStr of G holds the InternalRel
  of ComplRelStr H = (the InternalRel of ComplRelStr G)|_2 the carrier of
  ComplRelStr H
proof
  let G be RelStr, H be full SubRelStr of G;
  set IH = the InternalRel of H, ICmpH = the InternalRel of ComplRelStr H, cH
  = the carrier of H, IG = the InternalRel of G, cG = the carrier of G, ICmpG =
  the InternalRel of ComplRelStr G;
A1: ICmpH = IH` \ id cH by NECKLACE:def 8
    .= [:cH,cH:] \ IH \ id cH by SUBSET_1:def 4;
A2: ICmpG = IG` \ id cG by NECKLACE:def 8
    .= [:cG,cG:] \ IG \ id cG by SUBSET_1:def 4;
A3: cH c= cG by YELLOW_0:def 13;
  ICmpG |_2 the carrier of ComplRelStr H = ICmpG |_2 cH by NECKLACE:def 8
    .= ([:cG,cG:] \ IG) /\ [:cH,cH:] \ id cG /\ [:cH,cH:] by A2,XBOOLE_1:50
    .= ([:cG,cG:] /\ [:cH,cH:]) \ (IG /\ [:cH,cH:]) \ (id cG /\ [:cH,cH:])
  by XBOOLE_1:50
    .= ([:cG,cG:] /\ [:cH,cH:]) \ (IG /\ [:cH,cH:]) \ (id cG)|cH by Th1
    .= ([:cG,cG:] /\ [:cH,cH:]) \ IG|_2 cH \ id cH by A3,FUNCT_3:1
    .= ([:cG,cG:] /\ [:cH,cH:]) \ IH \ id cH by YELLOW_0:def 14
    .= [:cG /\ cH, cG /\ cH:] \ IH \ id cH by ZFMISC_1:100
    .= [:cH, cG /\ cH:] \ IH \ id cH by A3,XBOOLE_1:28
    .= ICmpH by A1,A3,XBOOLE_1:28;
  hence thesis;
end;
