reserve X for set;
reserve a,b,c,k,m,n for Nat;
reserve i for Integer;
reserve r for Real;
reserve p for Prime;

theorem Th19:
  for r being Complex holds
  OddEvenPowers(r,2*(k+1)+1) =
   <*r|^(2*k+2),-r|^(2*k+1)*> ^ OddEvenPowers(r,2*k+1)
  proof
    let r be Complex;
    set n = 2*(k+1)+1;
    set N = 2*k+1;
    set f = OddEvenPowers(r,n);
    set p = <*r|^(2*k+2),-r|^(2*k+1)*>;
    set q = OddEvenPowers(r,N);
A1: len f = n by Def3;
A2: len p = 2 by FINSEQ_1:44;
A3: len q = N by Def3;
A4: dom f = Seg (len p + len q) by A1,A2,A3,FINSEQ_1:def 3;
A5: for x being Nat st x in dom p holds f.x = p.x
    proof
      let x be Nat;
      assume x in dom p;
      then 1 <= x <= 2 by A2,FINSEQ_3:25;
      then x = 1+0 or ... or x = 1+1 by NAT_1:62;
      then per cases;
      suppose
A6:     x = 1;
        set m = n-1;
        1 <= n by NAT_1:11;
        then f.(2*0+1) = r|^m by Def3;
        hence thesis by A6;
      end;
      suppose
A7:     x = 2;
A8:     n = 2*k+1+2;
        then
A9:     2 <= n by NAT_1:11;
        reconsider m = n-2*1 as Element of NAT by A8;
        f.(2*1) = -r|^m by A9,Def3;
        hence thesis by A7;
      end;
    end;
    for x being Nat st x in dom q holds f.(len p + x) = q.x
    proof
      let x be Nat such that
A10:  x in dom q;
A11:  1 <= x by A10,FINSEQ_3:25;
A12:  x <= N by A3,A10,FINSEQ_3:25;
      x <= x+2 by NAT_1:11;
      then
A13:  1 <= x+2 by A11,XXREAL_0:2;
A14:  x+2 <= N+2 by A12,XREAL_1:6;
      reconsider m = N-x as Element of NAT by A12,INT_1:5;
      reconsider m2 = n-(x+2) as Element of NAT by A14,INT_1:5;
      per cases;
      suppose
A15:    x is odd;
        then
A16:    q.x = r|^m by A11,A12,Def3;
        f.(x+2) = r|^m2 by A13,A14,A15,Def3;
        hence f.(len p + x) = q.x by A16,FINSEQ_1:44;
      end;
      suppose
A17:    x is even;
        then
A18:    q.x = -r|^m by A11,A12,Def3;
        f.(x+2) = -r|^m2 by A13,A14,A17,Def3;
        hence f.(len p + x) = q.x by A18,FINSEQ_1:44;
      end;
    end;
    hence thesis by A4,A5,FINSEQ_1:def 7;
  end;
