 reserve a for non empty set;
 reserve b, x, o for object;
reserve R for right_zeroed add-associative right_complementable Abelian
  well-unital distributive associative non trivial non trivial doubleLoopStr;

theorem
    for R be non degenerated comRing holds Support(1_1(R)) = {1}
    proof
      let R be non degenerated comRing;
A1:   for o holds o in Support(1_1(R)) implies o in {1}
      proof
        let o;
        assume
A2:     o in Support(1_1(R)); then
        reconsider x = o as Element of NAT;
        x = 1
        proof
          assume x <> 1; then
          ((0_.R) +* (1,1.R)).x = (0_.R).x by FUNCT_7:32
               .= 0.R;
          hence contradiction by A2,POLYNOM1:def 4;
        end;
        hence thesis by TARSKI:def 1;
      end;
      for o holds o in {1} implies o in Support(1_1(R))
      proof
        let o;
        assume
A4:     o in {1}; then
A5:     o = 1 by TARSKI:def 1;
A6:     o in dom (0_.R) by A4; then
A7:     o in dom((0_.R) +* (1,1.R)) by FUNCT_7:30;
        ((0_.R) +* (1,1.R)).o = 1.R by A5,A6,FUNCT_7:31;
        hence thesis by A7,POLYNOM1:def 3;
      end;
      hence thesis by A1,TARSKI:2;
    end;
