reserve n for Element of NAT,
  i for Integer,
  a, b, r for Real,
  x for Point of TOP-REAL n;

theorem Th19:
  for n being non zero Element of NAT, r being positive Real
, x being Point of TOP-REAL n, f being Function of Tunit_circle(n),
Tcircle(x,r) st for a being Point of Tunit_circle(n), b being Point of TOP-REAL
  n st a = b holds f.a = r*b+x holds f is being_homeomorphism
proof
  let n be non zero Element of NAT, r be positive Real, x be Point
  of TOP-REAL n, f being Function of Tunit_circle(n), Tcircle(x,r) such that
A1: for a being Point of Tunit_circle(n), b being Point of TOP-REAL n st
  a = b holds f.a = r*b+x;
  defpred P[Point of TOP-REAL n,set] means $2 = r*$1+x;
  set U = Tunit_circle(n), C = Tcircle(x,r);
A2: for u being Point of TOP-REAL n ex y being Point of TOP-REAL n st P[u,y ];
  consider F being Function of TOP-REAL n, TOP-REAL n such that
A3: for x being Point of TOP-REAL n holds P[x,F.x] from FUNCT_2:sch 3(
  A2);
  defpred R[Point of TOP-REAL n,set] means $2 = 1/r*($1-x);
A4: for u being Point of TOP-REAL n ex y being Point of TOP-REAL n st R[u,y ];
  consider G being Function of TOP-REAL n, TOP-REAL n such that
A5: for a being Point of TOP-REAL n holds R[a,G.a] from FUNCT_2:sch 3(
  A4);
  set f2 = (TOP-REAL n) --> x;
  set f1 = id TOP-REAL n;
  dom G = the carrier of TOP-REAL n by FUNCT_2:def 1;
  then
A6: dom (G|Sphere(x,r)) = Sphere(x,r) by RELAT_1:62;
  for p being Point of TOP-REAL n holds G.p = 1/r * f1.p + (-1/r) * f2.p
  proof
    let p be Point of TOP-REAL n;
    thus 1/r * f1.p + (-1/r) * f2.p = 1/r*p + (-1/r)*f2.p
      .= 1/r*p + (-1/r)*x
      .= 1/r*p - 1/r*x by RLVECT_1:79
      .= 1/r*(p-x) by RLVECT_1:34
      .= G.p by A5;
  end;
  then
A7: G is continuous by TOPALG_1:16;
  thus dom f = [#]U by FUNCT_2:def 1;
A8: dom f = the carrier of U by FUNCT_2:def 1;
  for p being Point of TOP-REAL n holds F.p = r * f1.p + 1 * f2.p
  proof
    let p be Point of TOP-REAL n;
    thus r * f1.p + 1 * f2.p = r*f1.p + f2.p by RLVECT_1:def 8
      .= r*p + f2.p
      .= r*p + x
      .= F.p by A3;
  end;
  then
A9: F is continuous by TOPALG_1:16;
A10: the carrier of C = Sphere(x,r) by Th9;
A11: the carrier of U = Sphere(0.TOP-REAL n,1) by Th9;
A12: for a being object st a in dom f holds f.a = (F|Sphere(0.TOP-REAL n,1)).a
  proof
    let a be object such that
A13: a in dom f;
    reconsider y = a as Point of TOP-REAL n by A13,PRE_TOPC:25;
    thus f.a = r*y+x by A1,A13
      .= F.y by A3
      .= (F|Sphere(0.TOP-REAL n,1)).a by A11,A13,FUNCT_1:49;
  end;
A14: 1/r*r = 1 by XCMPLX_1:87;
  thus
A15: rng f = [#]C
  proof
    thus rng f c= [#]C;
    let b be object;
    assume
A16: b in [#]C;
    then reconsider c = b as Point of TOP-REAL n by PRE_TOPC:25;
    set a = 1/r * (c - x);
    |.a-0.TOP-REAL n.| = |.a.| by RLVECT_1:13
      .= |.1/r.|*|. c-x .| by TOPRNS_1:7
      .= 1/r*|. c-x .| by ABSVALUE:def 1
      .= 1/r*r by A10,A16,TOPREAL9:9;
    then
A17: a in Sphere(0.TOP-REAL n,1) by A14;
    then f.a = r*a+x by A1,A11
      .= r*(1/r)*(c-x)+x by RLVECT_1:def 7
      .= c-x+x by A14,RLVECT_1:def 8
      .= b by RLVECT_4:1;
    hence thesis by A11,A8,A17,FUNCT_1:def 3;
  end;
  thus
A18: f is one-to-one
  proof
    let a, b be object such that
A19: a in dom f and
A20: b in dom f and
A21: f.a = f.b;
    reconsider a1 = a, b1 = b as Point of TOP-REAL n by A11,A8,A19,A20;
A22: f.b1 = r*b1+x by A1,A20;
    f.a1 = r*a1+x by A1,A19;
    then r*a1 = r*b1+x-x by A21,A22,RLVECT_4:1;
    hence thesis by RLVECT_1:36,RLVECT_4:1;
  end;
A23: for a being object st a in dom (f") holds f".a = (G|Sphere(x,r)).a
  proof
    reconsider ff = f as Function;
    let a be object such that
A24: a in dom (f");
    reconsider y = a as Point of TOP-REAL n by A24,PRE_TOPC:25;
    set e = 1/r * (y - x);
A25: f is onto by A15;
    |.e-0.TOP-REAL n.| = |.e.| by RLVECT_1:13
      .= |.1/r.|*|. y-x .| by TOPRNS_1:7
      .= 1/r*|. y-x .| by ABSVALUE:def 1
      .= 1/r*r by A10,A24,TOPREAL9:9;
    then
A26: 1/r * (y - x) in Sphere(0.TOP-REAL n,1) by A14;
    then f.e = r*e+x by A1,A11
      .= r*(1/r)*(y-x)+x by RLVECT_1:def 7
      .= y-x+x by A14,RLVECT_1:def 8
      .= y by RLVECT_4:1;
    then ff".a = 1/r * (y - x) by A11,A8,A18,A26,FUNCT_1:32;
    hence f".a = 1/r*(y-x) by A25,A18,TOPS_2:def 4
      .= G.y by A5
      .= (G|Sphere(x,r)).a by A10,A24,FUNCT_1:49;
  end;
  dom F = the carrier of TOP-REAL n by FUNCT_2:def 1;
  then dom (F|Sphere(0.TOP-REAL n,1)) = Sphere(0.TOP-REAL n,1) by RELAT_1:62;
  hence f is continuous by A11,A8,A9,A12,BORSUK_4:44,FUNCT_1:2;
  dom (f") = the carrier of C by FUNCT_2:def 1;
  hence thesis by A10,A6,A7,A23,BORSUK_4:44,FUNCT_1:2;
end;
