
theorem Th1:
  for B being set st B is cap-closed for X being set, S being
  finite Subset-Family of X st X in B & S c= B holds Intersect S in B
proof
  let B be set;
  assume
A1: B is cap-closed;
  let X be set, S be finite Subset-Family of X such that
A2: X in B and
A3: S c= B;
  defpred P[set] means for sf being Subset-Family of X st sf = $1 holds
  Intersect sf in B;
A4: now
    let x be set, b be set such that
A5: x in S and
A6: b c= S and
A7: P[b];
    thus P[ b\/{x}]
    proof
      reconsider fx = {x} as Subset-Family of X by A5,ZFMISC_1:31;
      reconsider fb = b as Subset-Family of X by A6,XBOOLE_1:1;
      reconsider sx = x as Subset of X by A5;
A8:   Intersect (fb\/fx) = Intersect fb /\ Intersect fx by MSSUBFAM:8
        .= Intersect fb /\ sx by MSSUBFAM:9;
A9:   Intersect fb in B by A7;
      let sf be Subset-Family of X;
      assume sf = b\/{x};
      hence thesis by A1,A3,A5,A9,A8;
    end;
  end;
A10: S is finite;
A11: P[{}] by A2,SETFAM_1:def 9;
  P[S] from FINSET_1:sch 2(A10,A11,A4);
  hence thesis;
end;
