
theorem Th1:
  for X being non empty TopSpace, f be RealMap of X holds f is continuous iff
  for x being Point of X,V being Subset of REAL st
  f.x in V & V is open holds
  ex W being Subset of X st x in W & W is open & f.:W c= V
proof
  let X be non empty TopSpace,f be RealMap of X;
  hereby assume
A1: f is continuous;
  now let x be Point of X,V being Subset of REAL;
    set r = f.x;
    assume r in V & V is open;
    then
    consider r0 be Real such that
A2: 0<r0 & ].r-r0,r+r0.[ c= V by RCOMP_1:19;
    set S = ]. r-r0,r+r0 .[;
    take W= f"S;
    |.r-r.| < r0 by A2,COMPLEX1:44;
    then
    r in S by RCOMP_1:1;
    hence x in W by FUNCT_2:38;
    thus W is open by A1,PSCOMP_1:8;
    f.:(f"S) c= S by FUNCT_1:75;
    hence f.:W c= V by A2;
  end;
  hence for x being Point of X,V being Subset of REAL st
    f.x in V & V is open holds
      ex W being Subset of X st x in W & W is open & f.:W c= V;
  end;
  assume
A3:for x being Point of X,V being Subset of REAL st f.x in V & V is open holds
    ex W being Subset of X st x in W & W is open & f.:W c= V;
  now let Y be Subset of REAL;
    assume Y is closed;
    then
    Y`` is closed;
    then
A4: Y` is open;
    for x being Point of X st x in (f"Y)` ex W being Subset of X st
      W is a_neighborhood of x & W c= (f"Y)`
    proof
      let x be Point of X;
      assume x in (f"Y)`;
      then
      x in f"Y` by FUNCT_2:100; then
      f.x in Y` by FUNCT_2:38; then
      consider V being Subset of REAL such that
A5:     f.x in V & V is open & V c= Y` by A4;
      consider W being Subset of X such that
A6:     x in W & W is open & f.:W c= V by A3,A5;
      take W;
      thus W is a_neighborhood of x by A6,CONNSP_2:3;
      f.:W c= Y` by A5,A6;
      then
A7:   f"(f.:W) c= f"Y` by RELAT_1:143;
      W c= f"(f.:W) by FUNCT_2:42;
      then W c= f"Y` by A7;
      hence W c= (f"Y)` by FUNCT_2:100;
    end;
    then (f"Y)` is open by CONNSP_2:7;
    then (f"Y)`` is closed by TOPS_1:4;
    hence f"Y is closed;
  end;
  hence f is continuous;
end;
