
theorem
  for C being FormalContext for o being Object of C holds (
ObjectDerivation(C)).({o}) = {a where a is Attribute of C : o is-connected-with
  a}
proof
  let C be FormalContext;
  let o be Object of C;
  {o} c= the carrier of C
  proof
    let x be object;
    assume x in {o};
    then x = o by TARSKI:def 1;
    hence thesis;
  end;
  then reconsider t = {o} as Subset of the carrier of C;
A1: for x being object holds x in {a where a is Attribute of C : for o9 being
Object of C st o9 in t holds o9 is-connected-with a} implies x in {a where a is
  Attribute of C : o is-connected-with a}
  proof
    set o9 = the Element of t;
    let x be object;
    reconsider o9 as Object of C by TARSKI:def 1;
A2: o9 = o by TARSKI:def 1;
    assume x in {a where a is Attribute of C : for o9 being Object of C st o9
    in t holds o9 is-connected-with a};
    then
A3: ex x9 being Attribute of C st x9 = x & for o9 being Object of C st o9
    in t holds o9 is-connected-with x9;
    then reconsider x as Attribute of C;
    o9 is-connected-with x by A3;
    hence thesis by A2;
  end;
A4: for x being object holds x in {a where a is Attribute of C : o
  is-connected-with a} implies x in {a where a is Attribute of C : for o9 being
  Object of C st o9 in t holds o9 is-connected-with a}
  proof
    let x be object;
    assume x in {a where a is Attribute of C : o is-connected-with a};
    then
A5: ex x9 being Attribute of C st x9 = x & o is-connected-with x9;
    then reconsider x as Attribute of C;
    for o9 being Object of C st o9 in t holds o9 is-connected-with x by A5,
TARSKI:def 1;
    hence thesis;
  end;
  (ObjectDerivation(C)).t = {a where a is Attribute of C : for o9 being
  Object of C st o9 in t holds o9 is-connected-with a} by Def2;
  hence thesis by A1,A4,TARSKI:2;
end;
