reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (tan*cot) implies tan*cot is_differentiable_on Z & for x st x
  in Z holds((tan*cot)`|Z).x = 1/(cos.(cot.x))^2 *(-1/(sin.x)^2)
proof
  assume
A1: Z c= dom (tan*cot);
A2: for x st x in Z holds cos.(cot.x) <> 0
  proof
    let x;
    assume x in Z;
    then cot.x in dom (tan) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:1;
  end;
A3: for x st x in Z holds sin.x <> 0
  proof
    let x;
    assume x in Z;
    then x in dom (cos/sin) by A1,FUNCT_1:11;
    hence thesis by FDIFF_8:2;
  end;
A4: for x st x in Z holds tan*cot is_differentiable_in x
  proof
    let x;
    assume
A5: x in Z;
    then cos.(cot.x)<>0 by A2;
    then
A6: tan is_differentiable_in cot.x by FDIFF_7:46;
    sin.x <> 0 by A3,A5;
    then cot is_differentiable_in x by FDIFF_7:47;
    hence thesis by A6,FDIFF_2:13;
  end;
  then
A7: tan*cot is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((tan*cot)`|Z).x = 1/(cos.(cot.x))^2 *(-1/(sin.x) ^2)
  proof
    let x;
    assume
A8: x in Z;
    then
A9: cos.(cot.x)<>0 by A2;
    then
A10: tan is_differentiable_in cot.x by FDIFF_7:46;
A11: sin.x<>0 by A3,A8;
    then cot is_differentiable_in x by FDIFF_7:47;
    then diff(tan*cot,x) = diff(tan, cot.x)*diff(cot,x) by A10,FDIFF_2:13
      .=1/(cos.(cot.x))^2 * diff(cot,x) by A9,FDIFF_7:46
      .=1/(cos.(cot.x))^2 *(-1/(sin.x)^2) by A11,FDIFF_7:47;
    hence thesis by A7,A8,FDIFF_1:def 7;
  end;
  hence thesis by A1,A4,FDIFF_1:9;
end;
